[文本处理] 【已解决】求大佬帮忙写bat脚本，去除文本中自带规律序号的文本行的数字序号

@echo off
chcp 65001>nul
(for /f "tokens=1*" %%i in (test.txt) do (
    if "%%j"=="" (
        echo,%%i
    ) else (
        for /f "tokens=1,2 delims=.第章" %%I in ("%%i") do (
            if "%%I"=="%%J" (
                echo,第%%I章 %%j
                echo,
            ) else (
                setlocal enabledelayed
                set m=%%I
                set /a n=m
                echo,%%i %%j
                if "%%I"=="!n!" echo,
                endlocal
            )
        )
    )
))>New-test.txt
pause
复制代码

@echo off
chcp 65001>nul
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "test.txt"') do (
    if "%%b" equ "" (
        echo,
    ) else (
        for /f "tokens=1*" %%i in ("%%b") do (
            if "%%j"=="" (
                echo,%%i
            ) else (
                for /f "tokens=1,2 delims=.第章" %%I in ("%%i") do (
                    if "%%I"=="%%J" (
                        echo,第%%I章 %%j
                    ) else (
                        echo,%%i %%j
                    )
                )
            )
        )
    )
))>"New-test.txt"
复制代码

@echo off&pause&goto :haijimaru
$null=@'
:haijimaru
powershell "$l='%~dp0';type -literalpath '%~f0'|select -skip 1|out-string|iex"
pause&exit/b
'@

if(!$l){$l=$pwd.path+'\'}
[io.directory]::getfiles($l,'*.txt')|%{
$s=[regex]::replace([io.file]::ReadAllText($_,[text.encoding]::UTF8),'\d\d*\.(第\d\d*章)','$1')
[io.file]::WriteAllText("$l\__new_"+$_.split('\')[-1],$s,[text.encoding]::UTF8)
}
复制代码

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	setlocal
	for /f "tokens=1* delims=:" %%a in ('findstr /rnbc:"[0-9][0-9]*\." "%%i"') do (
		set _%%a=1
	)
	(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%%i"') do (
		if defined _%%a (
			set str=%%b
			setlocal enabledelayedexpansion
			echo !str:*.=!
			endlocal
		) else (
			echo=%%b
		)
	))>$
	move $ "%%i"
	endlocal
)
pause
复制代码

	for /f "tokens=1* delims=:" %%a in ('findstr /rnbc:"[0-9][0-9]*\." "%%i" ^|find ".第" ^|find "章"') do (
复制代码

@echo off&setlocal enabledelayedexpansion
chcp 65001>nul
for /f "tokens=1,2*delims=.:" %%i in ('findstr /ibn "[0-9][0-9]*\." test.txt') do set "_%%i=%%k"
(for /f "tokens=1*delims=:" %%i in ('findstr /in .* test.txt') do (
      if defined _%%i (
         for /f %%a in ("!_%%i!") do for /f "tokens=1*delims=0123456789" %%b in ("%%a") do (
              if "%%b%%c" == "第章" (echo !_%%i!)else echo %%j
         )
      )else  echo;%%j
))
pause
复制代码

@echo off 
powershell -c "$enc=[Text.Encoding]::UTF8;[IO.Directory]::EnumerateFiles($pwd,'*.txt').foreach({[IO.File]::WriteAllLines($_,([IO.File]::ReadAllLines($_,$enc) -replace '^\d+\.(?=第\d+章\s+.*)', ''),$enc) })"
pause
复制代码

@echo off
chcp 65001>nul
(for /f "tokens=1*" %%i in (test.txt) do (
    if "%%j"=="" (
        echo,%%i
    ) else (
        setlocal enabledelayedexpansion
        set "str=%%i"
        if "!str:~-1!"=="章" (
            echo,!str:*.=! %%j
            echo,
        ) else (
            echo,%%i %%j
        )
        endlocal
    )
))>New-test.txt
pause
复制代码