[文件操作] 求助批量创建文件夹移动文件的批处理怎样写才更简洁？[已解决]

@echo off
set "Folder=D:\abc"
md "E:\2022"
cd /d "E:\2022"
for /l %%a in (202201,1,202212) do (
    md "%%a"
    for %%i in ("%Folder%\*.xls") do copy "%%i" "%%~ni%%a.xls"
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set "file1=出库清单.xls"
set "file2=库存清单.xls"
set "file3=入库清单.xls"
set "file4=入库统表.xls"
set "file5=应付账款.xls"
for %%i in ("%file1%" "%file2%" "%file3%" "%file4%" "%file5%") do (
    if not exist %%i (
        goto :error1
    )
)

:begin
cls
set /p year=请输入年份：
if "%year%" equ "" goto :begin
if %year% lss 2020 (
    goto :begin
) else if %year% gtr 2100 (
    goto :begin
)
set "NewFolder=E:\%year%"
if exist "%NewFolder%" (
    goto :error2
) else (
    md "%NewFolder%"
)
for /l %%a in (101,1,112) do (
    set "month=%%a"
    set "month=!month:~1!"
    md "%NewFolder%\%year%.!month!"
    for %%i in ("%file1%" "%file2%" "%file3%" "%file4%" "%file5%") do (
        copy /y %%i "%NewFolder%\%year%.!month!\%%~ni%year%.!month!%%~xi"
    )
)
goto :end

:error1
echo 缺少文件。
goto :end

:error2
echo 已存在该年份文件。
goto :end

:end
pause
复制代码

@echo off
set "Folder=D:\abc"
md "E:\2022"
cd /d "E:\2022"
for /l %%a in (202201,1,202212) do (
    md "%%a"
    for %%i in ("%Folder%\*.xls") do copy "%%i" "%%a\%%~ni%%a.xls"
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
set xls1=出库清单.xls
set xls2=库存清单.xls
set xls3=入库清单.xls
set xls4=入库统表.xls
set xls5=应付账款.xls
set /p year=输入年份
md E:\%year%
for /l %%a in (101 1 112) do (
set n=%%a
set n=!n:~1!
set subdir=%year%.!n!
for %%i in (%xls1% %xls2% %xls3% %xls4% %xls5%) do  echo f|xcopy /q %%i E:\%year%\!subdir!\%%~ni!subdir!%%~xi 
)
pause
复制代码

@echo off
set "Folder=D:\abc"
md "E:\2022"
cd /d "E:\2022"
setlocal enabledelayedexpansion
for /l %%a in (202201,1,202212) do (
    set str=%%a
    set str=!str:~,4!.!str:~4!
    md "!str!"
    for %%i in ("%Folder%\*.xls") do copy "%%i" "!str!\%%~ni!str!.xls"
)
pause
复制代码