[文件操作] 请教各位大神如何缩编文件分类的批处理代码呢？

@echo off
setlocal enabledelayedexpansion
for /d %%x in (*) do (
    pushd %%x
    for %%i in (*) do (
        set str=%%i
        if "!str!"=="!str:_x=!" (
            for /f "tokens=4 delims=-" %%a in ("%%i") do (
                if not exist "%%a" md "%%a"
                move "%%i" "%%a"
            )
        ) else (
            for /f "tokens=4,5 delims=-" %%a in ("%%i") do (
                set y=%%b
                if not exist "%%a-!y:~,-1!" md "%%a-!y:~,-1!"
                move "%%i" "%%a-!y:~,-1!"
            )
        )
    )
popd
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /d %%x in (*) do (
    pushd %%x
    for %%i in (*) do (
        set str=%%i
        if "!str!"=="!str:_x=!" (
            for /f "tokens=4 delims=-" %%a in ("%%i") do (
                if not exist "%%a" md "%%a"
                move "%%i" "%%a"
            )
        ) else (
            for /f "tokens=4,5,6 delims=-" %%a in ("%%i") do (
                echo,%%a|findstr /v /be [0-9][0-9]*>nul&&(set "str1=%%a"&set "str2=%%b")||(set "str1=%%b"&set "str2=%%c")
                if not exist "!str1!-!str2:~,-1!" md "!str1!-!str2:~,-1!"
                move "%%i" "!str1!-!str2:~,-1!"
            )
        )
    )
popd
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /d %%i in (*) do (
    pushd %%i
    for %%j in (*) do (
        for /f "tokens=4,5,6,7 delims=-" %%a in ("%%j") do (
            set "x=%%d"&set "x=!x:~-3!"
            set "x1=%%a"&set "x2=%%b"&set "x3=%%c"
            if "!x!"=="DPI" (
                if "!x3!"=="OneSize" (
                    if not exist "!x2!" md "!x2!"
                    move "%%j" "!x2!"
                ) else if "!x3:~-4!"=="inch" (
                    if not exist "!x3!" md "!x3!"
                    move "%%j" "!x3!"
                ) else (
                    if not exist "!x2!-!x3!" md "!x2!-!x3!"
                    move "%%j" "!x2!-!x3!"
                )
            ) else (
                if "!x2!"=="OneSize" (
                    if not exist "!x1!" md "!x1!"
                    move "%%j" "!x1!"
                ) else if "!x2:~-4!"=="inch" (
                    if not exist "!x2!" md "!x2!"
                    move "%%j" "!x2!"
                ) else (
                    if not exist "!x1!-!x2!" md "!x1!-!x2!"
                    move "%%j" "!x1!-!x2!"
                )
            )
        )
    )
popd
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /d %%i in (*) do (
    pushd %%i
    for %%j in (*) do (
        for /f "tokens=4,5,6,7 delims=-" %%a in ("%%j") do (
            set "x=%%d"&set "x=!x:~-3!"
            if "!x!"=="DPI" (
                set "x1=%%b"&set "x2=%%c"
            ) else (
                set "x1=%%a"&set "x2=%%b"
            )
            if "!x2!"=="OneSize" (
                if not exist "!x1!" md "!x1!"
                move "%%j" "!x1!"
            ) else if "!x2:~-4!"=="inch" (
                if not exist "!x2!" md "!x2!"
                move "%%j" "!x2!"
            ) else (
                if not exist "!x1!-!x2!" md "!x1!-!x2!"
                move "%%j" "!x1!-!x2!"
            )
        )
    )
popd
)
pause
复制代码

@echo off
@for /f "tokens=*" %%a in ('dir /b/a-d/oN *.jpg') do (
    @for /f "delims=*" %%b in ('echo %%a^|grep -Eo "D805[01]"') do (
    if not exist "%%b" echo 创建"D8050-D8051" & md "D8050-D8051"&move "%%a" "D8050-D8051"
    )
    @for /f "delims=*" %%c in ('echo %%a^|grep -oE "ZY1370|ZY003-S"') do (
    if not exist "%%c" echo 创建"ZY1370-ZY003-S" & md "ZY1370-ZY003-S"&move "%%a" "ZY1370-ZY003-S"
    )
    @for /f "delims=*" %%d in ('echo %%a^|grep -oE "[A-Z]+[0-9]+-?-[0-9]+_x[0-9]+"') do (
    if not exist "%%d" echo 创建"%%d" & md "%%d"&move "%%a" "%%d"
    )
    @for /f "delims=*" %%e in ('echo %%a^|grep -Po "(?<=-[1-9]-|LT001)ZY003-M|[^-]+inch"') do (
    if not exist "%%e" echo 创建"%%e" & md "%%e"&move "%%a" "%%e"
    )
)
@for /f "tokens=*" %%i in ('dir /b/a-d/oN *.jpg') do (
    @for /f "delims=*" %%j in ('echo %%i^|grep -Po "(?<=-[1-9]-)[A-Z]+[0-9]+"') do (
    if not exist "%%j" echo 创建"%%j" & md "%%j"&move "%%i" "%%j"
    )
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /d %%i in (*) do (
    pushd %%i
    for %%j in (*) do (
        for /f "tokens=4,5,6,7 delims=-" %%a in ("%%j") do (
            set "x=%%d"&set "x=!x:~-3!"
            if "!x!"=="DPI" (
                set "x1=%%b"&set "x2=%%c"
            ) else (
                set "x1=%%a"&set "x2=%%b"
            )
            if "!x2!"=="OneSize" (
                if "!x1!"=="D8050" (
                    if not exist "D8050-D8051" md "D8050-D8051"
                    move "%%j" "D8050-D8051"
                ) else if "!x1!"=="D8051" (
                    if not exist "D8050-D8051" md "D8050-D8051"
                    move "%%j" "D8050-D8051"
                ) else if "!x1!"=="ZY1370" (
                    if not exist "ZY1370-ZY003-S" md "ZY1370-ZY003-S"
                    move "%%j" "ZY1370-ZY003-S"
                ) else (
                    if not exist "!x1!" md "!x1!"
                    move "%%j" "!x1!"
                )
            ) else if "!x2:~-4!"=="inch" (
                if not exist "!x2!" md "!x2!"
                move "%%j" "!x2!"
            ) else (
                if "!x1!-!x2!"=="ZY003-S" (
                    if not exist "ZY1370-ZY003-S" md "ZY1370-ZY003-S"
                    move "%%j" "ZY1370-ZY003-S"
                ) else (
                    if "!x2:~-1!"=="_" set "x2=!x2:~0,-1!"
                    if not exist "!x1!-!x2!" md "!x1!-!x2!"
                    move "%%j" "!x1!-!x2!"
                )
            )
        )
    )
popd
)
pause
复制代码