批处理之家 » BAT求助&讨论 » 用批处理形成另一个批处理

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 2

帖子: 107
积分: 126
技术: 0
捐助: 0
注册时间: 2011-2-7

1楼 跳转到 » 倒序看帖

字体大小: tT

发表于 2020-8-3 16:01 | 只看该作者

[文本处理] 用批处理形成另一个批处理

本帖最后由 winsfly 于 2020-8-3 17:23 编辑

我想把下面的这段批处理用批处理输出到另一个批处理

@echo off
setlocal enabledelayedexpansion

for /l %%i in (1,1,100) do if not exist "对比结果%%i" set "folder=对比结果%%i" & goto :next
:next
if exist "对比结果\" rename "对比结果" "%folder%"
 
md 对比结果

for /f "delims=" %%i in (渠道交单数据.txt) do (find /i "%%i" 对比结果\渠道交单已去重.txt||echo %%i>>对比结果\渠道交单已去重.txt)




(for /f %%i in ('type "对比结果\渠道交单已去重.txt"') do (
    set "OldStr=%%i"
    set "NewStr=!OldStr:~0,3!....!OldStr:~7,4!"
    findstr "!NewStr!" 系统后台数据.txt >nul 2>&1 || echo,%%i
))>"对比结果\未入系统数据.txt"


findstr /g:对比结果\渠道交单已去重.txt 后台错误数据.txt >对比结果\渠道错误数据.txt

set rowa=0
for /f %%a in (对比结果\渠道交单已去重.txt) do if '%%a' neq '' set /a rowa+=1

set rowb=0
for /f %%b in (渠道交单数据.txt) do if '%%b' neq '' set/a rowb+=1
echo 渠道交单%rowb%单 >对比结果\对比结果总结.txt

set /a rowd=%rowb%-%rowa%
echo 渠道交单重复%rowd%单 >>对比结果\对比结果总结.txt 

set rowc=0
for /f %%c in (对比结果\渠道错误数据.txt) do if '%%c' neq '' set/a rowc+=1
echo 渠道交单错误%rowc%单 >>对比结果\对比结果总结.txt

set rowe=0
for /f %%d in (对比结果\未入系统数据.txt) do if '%%d' neq '' set/a rowe+=1
echo 未入系统%rowe%单 >>对比结果\对比结果总结.txt

set /a youxiao=%rowb%-%rowd%-%rowc%-%rowe%
echo 统计有效为%youxiao%单 >>对比结果\对比结果总结.txt
exit
复制代码

把上面所有命令输出为另一个批处理1.cmd
不能用more语句，因为上面这些代码在另外一个批处理不同地方

Rank: 5 Rank: 5

帖子: 595
积分: 804
技术: 38
捐助: 0
注册时间: 2018-11-29

2楼

发表于 2020-8-3 16:35 | 只看该作者

(Echo for /l %%%%i in ^(1,1,100^)do if not exist "比对%%%%i" set "folder=比对%%%%i"^&goto :next)>1.bat
复制代码

Rank: 12

帖子: 14936
积分: 46143
技术: 857
捐助: 745
注册时间: 2008-6-9

3楼

发表于 2020-8-3 17:09 | 只看该作者

回复 1# winsfly

不能用more语句的原因是？

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 2

帖子: 107
积分: 126
技术: 0
捐助: 0
注册时间: 2011-2-7

4楼

发表于 2020-8-3 17:14 | 只看该作者

回复 3# Batcher
因为我是一个庞大的批处理，只是想把这个批处理很多行的命令原封不动重新输出到另外一个批处理中

Rank: 2

帖子: 107
积分: 126
技术: 0
捐助: 0
注册时间: 2011-2-7

5楼

发表于 2020-8-3 17:16 | 只看该作者

回复 2# smss
%%i可以用%%%%i
假如是%i% 这种变量就不行了吧？

Rank: 12

帖子: 14936
积分: 46143
技术: 857
捐助: 745
注册时间: 2008-6-9

6楼

发表于 2020-8-3 19:36 | 只看该作者

回复 5# winsfly

%%i%%

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 12

帖子: 14936
积分: 46143
技术: 857
捐助: 745
注册时间: 2008-6-9

7楼

发表于 2020-8-3 19:37 | 只看该作者

回复 4# winsfly

more也可以实现吧，看不出哪里有冲突呢

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 5 Rank: 5

帖子: 283
积分: 507
技术: 10
捐助: 0
注册时间: 2008-2-16

8楼

发表于 2020-8-4 08:43 | 只看该作者

第七行有个空格，是不是因为你这个原因？

Rank: 4

帖子: 314
积分: 408
技术: 19
捐助: 0
注册时间: 2014-11-3

9楼

发表于 2020-8-4 10:52 | 只看该作者

不确定地方也可以用more来输出啊。设置一个开始结束标记。用findstr /n找出其所在行数后不就可以用more进行定位输出了吗。

echo,hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5x>in.com

Rank: 2

帖子: 107
积分: 126
技术: 0
捐助: 0
注册时间: 2011-2-7

10楼

发表于 2020-8-4 12:04 | 只看该作者

回复 8# 窄口牛
大侠，特别谢谢您，不辞麻烦地帮我全部搞好了，

赞赞赞赞赞赞

Rank: 5 Rank: 5

帖子: 595
积分: 804
技术: 38
捐助: 0
注册时间: 2018-11-29

11楼

发表于 2020-8-4 12:58 | 只看该作者

(Echo @Echo off^&SetLocal EnableDelayedExpansion
Echo for /l %%%%i in ^(1,1,100^)do if not exist "对比结果%%%%i" set "folder=对比结果%%%%i"^&goto :next
Echo :next
Echo if exist "对比结果\" ren "对比结果" "%%folder%%"
Echo md 对比结果
Echo for /f "delims=" %%%%i in ^(渠道交单数据.txt^)do ^(find /i "%%%%i" 对比结果\渠道交单已去重.txt^|^|echo %%%%i^>^>对比结果\渠道交单已去重.txt^)
Echo ^(for /f %%%%i in ^('type "对比结果\渠道交单已去重.txt"'^)do ^(set "OldStr=%%%%i"^&set "NewStr=!OldStr:~0,3!....!OldStr:~7,4!"^&findstr "!NewStr!" 系统后台数据.txt ^>nul 2^>^&1^|^|echo,%%%%i^)^)^>"对比结果\未入系统数据.txt"
Echo findstr /g:对比结果\渠道交单已去重.txt 后台错误数据.txt ^>对比结果\渠道错误数据.txt
Echo set rowa=0
Echo for /f %%%%a in ^(对比结果\渠道交单已去重.txt^)do if '%%%%a' neq '' set /a rowa+=1
Echo set rowb=0
Echo for /f %%%%b in ^(渠道交单数据.txt^)do if '%%%%b' neq '' set/a rowb+=1
Echo echo 渠道交单%%rowb%%单 ^>对比结果\对比结果总结.txt
Echo set /a rowd=%%rowb%%-%%rowa%%
Echo echo 渠道交单重复%%rowd%%单 ^>^>对比结果\对比结果总结.txt 
Echo set rowc=0
Echo for /f %%%%c in ^(对比结果\渠道错误数据.txt^)do if '%%%%c' neq '' set/a rowc+=1
Echo echo 渠道交单错误%%rowc%%单 ^>^>对比结果\对比结果总结.txt
Echo set rowe=0
Echo for /f %%%%d in ^(对比结果\未入系统数据.txt^)do if '%%%%d' neq '' set/a rowe+=1
Echo echo 未入系统%%rowe%%单 ^>^>对比结果\对比结果总结.txt
Echo set /a youxiao=%%rowb%%-%%rowd%%-%%rowc%%-%%rowe%%
Echo echo 统计有效为%%youxiao%%单 ^>^>对比结果\对比结果总结.txt
Echo exit
Echo pause)>1.bat
pause
复制代码