[文本处理] [已解决]批处理怎么获取目录下文件大小少于5M的文件夹列表？

@echo off&setlocal enabledelayedexpansion&set m=1048576
(for /f "tokens=*" %%i in ('dir /ad /b') do (set size=000
for /f "eol=0tokens=3" %%j in ('dir /s/a/-c "%%i" 2^>nul^| findstr /i "个文件.*字节$"') do set "size=%%j00"
if !size! geq 102400 (if !size! geq 104857600 (set s=MB&set t=!size!&set len=!t:~9!98765432100&set /alen=9+!len:~10,1!&set/a "r=!t:~,8!%%m,size=!t:~,8!/m"
for /l %%j in (8 1 !len!) do set/a "q=!r!!t:~%%j,1!/m,r=!r!!t:~%%j,1!%%m"&set "size=!size!!q!"
if !size! geq 102400 set s=GB&set /asize/=1024)else set s=KB&set /asize/=1024)else set s=Byte
if "!size!" GTR "5" echo %%i !size:~,-2!.!size:~-2! !s!))>结果.TXT&start "" 结果.TXT&pause
复制代码

@echo off
setlocal enabledelayedexpansion
set "dir=D:\Notepad++"
set "max=5242880"
REM for /r "%dir%" /d %%i in ("*") do call :getFolderSize "%%i"
for /d %%i in ("%dir%\*") do call :getFolderSize "%%i"
pause&exit
:getFolderSize
set "size=0"
for /r "%~1" %%i in ("*") do ( set /a "size+=%%~zi" & if !size! gtr %max% goto :eof )
if !size! leq 1024 ( echo !size!B	%~1 & goto :eof )
if !size! leq 1048576 ( set /a "size/=1024" & echo !size!KB	%~1 & goto :eof )
set /a "size=!size!/1024/1024" & echo !size!MB	%~1 & goto :eof )
复制代码

@echo off
setlocal enabledelayedexpansion
set "dir=%~dp0"
set "max=5242880"
(
REM for /r "%dir%" /d %%i in ("*") do call :getFolderSize "%%i"
for /d %%i in ("%dir%*") do call :getFolderSize "%%i"
)>"%~dp0dirList.txt"
type "%~dp0dirList.txt"
echo ----------------------
echo out file: %~dp0dirList.txt
echo ----------------------
pause&exit

:getFolderSize
set "size=0"
for /r "%~1" %%i in ("*") do ( set /a "size+=%%~zi" & if !size! gtr %max% goto :eof )
if !size! leq 1024 ( set "unit=B" & goto :show )
if !size! leq 1048576 ( set "unit=KB" & set /a "size=!size!*100/1024" & set "size=!size:~0,-2!.!size:~-2!" & goto :show )
set "unit=MB" & set /a "size=!size!*100/1024/1024" & set "size=!size:~0,-2!.!size:~-2!"
:show
set "size=%size%%unit%          "
echo %size:~0,10% %~1
复制代码

@echo off
setlocal enabledelayedexpansion
set "dir=%~dp0"
set "max=5242880"
( for /d %%i in ("%dir%\*") do call :getFolderSize "%%i" )>"%~dp0dirList.txt"
type "%~dp0dirList.txt"
echo ----------------------
echo out file: %~dp0dirList.txt
echo ----------------------
pause&exit

:getFolderSize
set "size=0"
for /r "%~1" %%i in ("*") do ( set /a "size+=%%~zi" & if !size! gtr %max% goto :eof )
echo %~nx1
复制代码