[文本处理] 批处理如何提取文本中第二列/第2列符合指定条件的行内容

' 2>nul&cls&type "a.txt"|cscript -nologo -e:vbs "%~0">new.txt&exit
set regexp=new regexp
set ws=wsh.stdin
with regexp
    do
    .global=-1
    read=ws.readline
        .pattern="\b\w{8,}$"
        if .test(read) then
            .pattern="\b(\d+|[a-zA-Z][a-zA-Z]+)$"
            if not .test(read) then
                .pattern="^.* (.*)$"
                r=.replace(read,"$1")
                .pattern="([A-Z].*|.*[A-Z].*)"
                if not .test(r) then
                    .pattern="(^[a-z]+)(.*)"
                    a=.replace(r,"$1")
                    b=.replace(r,"$2")
                    .pattern="\d*"
                    s=.replace(a,empty)
                    p=ucase(left(s,1))&right(s,len(s)-1)
                    read=replace(read,r,replace(r,s,p))
                end if
                wsh.echo read
            end if
        end if
    loop until ws.atendofstream
end with
复制代码

@set @n=0; /* & echo off & cscript -nologo -e:jscript "%~0"<1.txt>2.txt & pause & exit/b & rem */

WScript.StdIn.ReadAll().replace(/(.*\s+)([^\s]{8,})\r\n/g, function($0,$1,$2){
	$2.replace(/((?:\d+([a-zA-Z])|([a-zA-Z])[\da-zA-Z]*\d)[\da-zA-Z]*)/, function(a,b,c,d){
		WSH.Echo($1+$2.replace(c?c:d, (c?c:d).toUpperCase()))
	})
});
复制代码

@echo off & setlocal enabledelayedexpansion
:: 借前辈计算字符串长度方法http://www.bathome.net/thread-11799-1-1.html
set "_length=set $=000102030405060708090a0b0c0d0e0f101112131415161718191a1b1c1d^!$^!^!$^!&set/a#len=0x^!$:~-60,2^!"
set upls=ABCDEFGHIJKLMNOPQRSTUVWXYZ
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set "#%%i=%%i"
for /f "tokens=1,*delims= " %%i in (1.txt) do (
	set "str=%%j"
	if "!str:~7!" neq "" (
		set "$=%%j"&(%_length%)&set /a len=!#len!-1
		for /l %%a in (0,1,!len!) do (
			if not defined end (
				set "letter=!str:~%%a,1!"
				set /a n=letter
				if !n!==!letter! (
					set /a "f|=1"
					if defined l (
						set s=!s!!letter!
					) else set p=!p!!letter!
				) else (
					set /a "f|=2"
					if not defined l (
						set l=!letter!
					) else set s=!s!!letter!
					for %%i in (!letter!) do if "!upls!"=="!upls:%%i=%%i!" set "u=1"
				)
				if "!f!"=="3" (
					if defined u set end=1
				)
			)
		)
		if "!f!"=="3" (
			if not defined end for %%i in (!l!) do set str=!p!!#%%i!!s!
		) else set "str="
		set p=&set l=&set s=&set f=&set u=&set "end="
		if defined str echo;%%i  !str!
	)
)
pause & exit /b
复制代码

@echo off
setlocal enabledelayedexpansion
(for %%a in (a_A b_B c_C d_D e_E f_F g_G h_H i_I j_J k_K l_L m_M n_N o_O p_P q_Q r_R s_S t_T u_U v_V w_W x_X y_Y z_Z) do echo;%%a)>temp.txt
for /f "tokens=1,2 delims= " %%a in (111.txt) do (
    setlocal
    set/a 1%%b1>nul 2>nul||set number=yes 
    echo;%%b|findstr [0-9]>nul 2>nul&&set english=yes 
    if defined number (
        set "number="
        if defined english ( 
            set "english=" &set "long=" 
            call :eightcheck %%b
            if defined long (
                set "capital="
                call :capscheck %%b
                if defined capital ( 
                    echo;%%a    %%b
                ) else (
	   call :capschange %%b
                )           
            )
        )
    )
endlocal
)>>222.txt
echo;处理完毕&pause>nul&exit /b 

:eightcheck
set "a=" & set str=%1
:loop
set /a a+=1
set str=%str:~0,-1%
if "%str%"=="" (
if !a! geq 8 set long=yes 
 ) else goto loop
goto :eof

:capscheck
for /f "tokens=2 delims=_" %%c  in (temp.txt) do (
    echo;%1|find "%%c">nul 2>nul&&set capital=yes
)
goto :eof

:capschange
set var=%1 & set head=%1
for /l %%d in (0 1 9) do set head=!head:%%d=!
set head=%head:~0,1%

for /f "tokens=1,2 delims=_" %%i in ('findstr /i "%head%" temp.txt') do (
    set var=!var:%%i=%%j!
    echo;%%a    !var!
)
goto :eof
复制代码

sed -r "/^\S+\s+([A-Za-z]+|[0-9]+|.{0,7})$/d;s/(^\S+\s+[0-9]*)([a-z])([a-z0-9]*)$/\1\u\2\3/" a.txt
复制代码

$s = [IO.File]::ReadAllText('a.txt', [Text.Encoding]::Default);
$s = [regex]::Replace($s, '(?m)^\S+\s+(\S{0,7}|[a-zA-Z]+|\d+)\r?$', '');
$s = [regex]::Replace($s, '(?m)(?<=^\S+\s+\d*)[a-z](?=[a-z0-9]*\r?$)', { param($a); $a.Value.ToUpper() });
$s | Out-File b.txt
复制代码

@echo off & setlocal enabledelayedexpansion

for %%i in (Q W E R T Y U I O P A S D F G H J K L Z X C V B N M) do set "_%%i=%%i"

for /f "tokens=1,2" %%i in ('type a.txt ^| findstr /v "\<[a-Z][a-Z]*$ \<[0-9][0-9]*$"') do (
    set "s=%%j"
    for /f "delims=QWERTYUIOPASDFGHJKLZXCVBNM" %%k in ("#%%j#") do (
        if not "!s:~7!" == "" if "%%k" == "#%%j#" (
            for /f "tokens=*delims=1234567890" %%L in ("%%j") do (
                set "s1=!s:%%L=!"
                set "s2=%%L"
            )
            for %%L in ("!s2:~0,1!") do echo;%%i	!s1!!_%%~L!!s2:~1!
        ) else echo;%%i	%%j
    )
)
pause
复制代码

@echo off & setlocal enabledelayedexpansion
for %%i in (Q W E R T Y U I O P A S D F G H J K L Z X C V B N M) do set "_%%i=%%i"
for /f "tokens=1,2" %%i in (a.txt) do (
	set "s=%%j"
	if not "!s:~7!" == "" (
		for /f "tokens=1delims=QWERTYUIOPASDFGHJKLZXCVBNMqwertyuiopasdfghjklzxcvbnm" %%k in ("%%j") do (
			for /f "tokens=*delims=1234567890" %%a in ("%%j") do if "%%a" neq "" (
				set "l=%%a"
				for %%b in ("!l:~0,1!") do echo;%%i	!s:%%a=!!_%%~b!!l:~1!
			)
		)
	)
)
pause & exit /b
复制代码

@echo off & setlocal enabledelayedexpansion
for %%z in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do set _%%z=%%z
for /f "tokens=1,2 delims= " %%a in (111.txt) do (
    echo;%%b|findstr [a-Z]|findstr [0-9] >nul&&set mix=yes||set "mix="
    if defined mix (
            call :eightcheck %%b
            if defined long call :capschange %%a %%b
    )
)
echo;处理完毕 & pause>nul & exit /b 
:eightcheck
set str=%1
if not "%str:~7,1%"=="" (set long=yes ) else (set "long=" )
goto :eof
:capschange
set var=%2 & set head=%2
for /l %%d in (0 1 9) do set head=!head:%%d=!
    set head=%head:~0,1%
    call set capshead=%%_%head%%%
    call set var=%%var:%head%=%capshead%%%
    echo;%1    %var%
)
goto :eof
复制代码