[文件操作] [已解决]批处理如何提取htm文件里的指定内容/字符串来重命名该文件？

@if (0)==(0) echo off
for /f "delims=" %%i in ('dir /b *.htm^|cscript //nologo //e:jscript "%~f0"') do ren %%i
pause & exit
@end

var getContent = function(strFile){
    var ado = new ActiveXObject('ADODB.Stream');
    ado.Type = 2;
    ado.Charset = 'UTF-8';
    ado.Open();
    ado.LoadFromFile(strFile);
    var s = ado.ReadText(-1);
    var title = s.match(/<title>(.+)<\/title>/i)[1];
    var author = [];
    var reg = /'color:#003300'>(.+?)</ig;
    while(arr = reg.exec(s)){author.push(arr[1])}
    ado = null;
    return (title + '--' + author).replace(/[\/\\|*?<>":]/g, '')
}

while(!WSH.StdIn.AtEndOfStream){
    var f = WSH.StdIn.ReadLine();
    var ext = f.replace(/.+(\.html?)$/i, '$1');
    WSH.Echo('"' + f + '" "' + getContent(f) + ext + '"');
}
复制代码

@echo off & setlocal enabledelayedexpansion
set "reg=(?<=<title>).+(?=</title>)|(?<='color:#003300'>).+?(?=<)"

for /f "delims=" %%i in ('dir /b *.htm') do (
    set "newName="
    for /f "delims=" %%j in ('win_iconv -c -f utf8 -t gb2312 "%%i" ^| grep -ioP "%reg%"') do (
        if not defined newName (set newName=%%j--)else set "newName=!newName!%%j,"
    )
    for %%j in (/ \ : ^| ^< ^> ^") do set "newName=!newName:%%j=!"
    set "newName=!newName:?=!"
    ren "%%i" "!newName:~0,-1!%%~xi"
)
pause
复制代码

@echo off
set "r1=(?i)<title>(.+)</title>"
set "r2=(?i)''color:#003300''>(.+?)<"

PowerShell -c "dir @('*.htm','*.html')|%%{$a=type $_ -encoding utf8;$b=[regex]::match($a,'%r1%').groups[1].value;$c=([regex]::matches($a,'%r2%')|%%{$_.groups[1].value}) -join ',';ren $_ -newName (($b+'--'+$c+$_.Extension) -replace '[/\\|*?<>:\"]')}"
pause
复制代码