[文本处理] 【已解决】批处理如何将含有关键词的txt文件移进以关键词为名的文件夹？

@echo off&setlocal enabledelayedexpansion
set /p cho=请输入关键词：
for %%a in (*.txt) do (
	set /a i+=1 &set gk=0
	type "%%a"|find /i "!cho!" && set gk=1
	if !gk! equ 1 (
		if not exist "!cho!" (md "!cho!")
		move "%%a" "!cho!\%%~na-!i!.txt"
	)
)
echo 执行完毕！
pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set /p cho=请输入关键词：
for /f "delims=" %%a in ('dir /a-d /b /s *.txt') do (
	set gk=0
	type "%%a"|find /i "!cho!" && set gk=1
	if !gk! equ 1 (
		if not exist "!cho!" (md "!cho!")
		if exist "!cho!\%%~na.txt" (
			set k=1
			for /l %%i in (1 1 255) do (
				if !k! equ 1 (
					if not exist "!cho!\%%~na-%%i.txt" (
						set "SN=%%i"
						set k=0
					)
				)		
			)
			move "%%a" "!cho!\%%~na-!SN!.txt"
		) else (
			move "%%a" "!cho!\%%~na.txt"
		)
	)
)
echo 执行完毕！
pause>nul
复制代码

@echo off
set "keyWord=ABC"
for /f "delims=" %%i in ('findstr /i /s /m /c:"%keyWord%" *.txt') do (
    set "name=%%~ni"
    setlocal enabledelayedexpansion
    set "newName=!name!%%~xi"
    md "D:\!keyWord!" 2>nul
    for /l %%j in (1 1 100) do (
        if exist "D:\!keyWord!\!newName!" set "newName=!name!_%%j%%~xi"
    )
    for %%j in ("D:\!keyWord!\!newName!") do (
        endlocal & move "%%i" "%%~fj"
    )
)
pause
复制代码