【练习-038】批处理随机生成工资流水帐目并汇总

@echo off&setlocal enabledelayedexpansion
set mon=31 28 31 30 31 30 31 31 30 31 30 31
set ren=甲 乙 丙 丁 戊 己 庚 辛 壬 癸
echo 正在准备。。。
for %%a in (%mon%) do (
        set/a m+=1
        for /l %%b in (1,1,%%a) do (
                set/a n+=1
                for %%c in (%ren%) do (
                        set #!random!#%%c#!n!=2009-!m!-%%b
                )
        )
)
echo 正在生成。。。
(echo 姓名        工资        日期
for /f "skip=2650 tokens=2,4 delims==#" %%a in ('set #') do (
        set/a r=!random!%%100+1,$=!random!%%10
        if !$! equ 0 (set $=-) else (set $=)
        echo %%a        !$!!r!        %%b
))>a.xls
:end
echo ok!!
pauseCOPY

@echo off
if "%1"=="#批处理#" goto :sub
setlocal enabledelayedexpansion
set mon=31 28 31 30 31 30 31 31 30 31 30 31
set men=甲 乙 丙 丁 戊 己 庚 辛 壬 癸
for %%a in (%mon%) do (
        set/a m+=1
        for /l %%b in (1,1,%%a) do (
                set/a n+=1
                set #!n!=!m!-%%b
        )
)
set 0=-&set l=1000
(echo 姓名        工资        日期
for /f "tokens=2,3 delims==" %%a in ('%~n0 #批处理#^|sort') do (
        set/a $=!random!%%10,r=!random!%%100+1
        for %%c in (!$!) do (
                echo %%a        !%%c!!r!        2009-%%b
        )
        set /a l-=1,1/l||goto :ok
))>a.xls
 
:ok
start a.xls
goto :eof
 
:sub
set/a k=n
for %%a in (%men%) do (
        setlocal enabledelayedexpansion
        set/a r=!random!%%20+100
        for /l %%b in (1,1,!r!) do (
                set/a r=!random! %% k + 1
                for /f "tokens=1,2" %%b in ("!r! !k!") do (
                        echo !random!=%%a=!#%%b!
                        set #%%b=!#%%c!
                        set/a k-=1
                )
        )        
        endlocal
)COPY

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2,3" %%a in (a.xls) do (
        for /f "tokens=2 delims=-" %%d in ("%%c") do (set/a #%%a#%%d+=%%b)
)
set men=甲 乙 丙 丁 戊 己 庚 辛 壬 癸
set mon=一 二 三 四 五 六 七 八 九 十 十一 十二
(echo 月份        %mon: =        %        小计
for %%a in (%men%) do (set line=%%a&set coun=
        for /l %%b in (1,1,12) do (
                set line=!line!        !#%%a#%%b!
                set/a coun+=#%%a#%%b,##%%b+=#%%a#%%b
        )
        echo !line!        !coun!
)
set line=合计&set coun=
for /l %%a in (1,1,12) do (set line=!line!        !##%%a!&set/a coun+=##%%a)
echo !line!        !coun!
)>b.xls
start b.xlsCOPY

 
@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2,3" %%a in (a.xls) do (
 for /f "tokens=2 delims=-" %%d in ("%%c") do (set/a #%%a#%%d+=%%b,#合计#%%d+=%%b)
)
set men=甲 乙 丙 丁 戊 己 庚 辛 壬 癸
set mon=一 二 三 四 五 六 七 八 九 十 十一 十二
(echo 月份 %mon: = % 小计
for %%a in (%men% 合计) do (set line=%%a&set coun=
 for /l %%b in (1,1,12) do (
  set line=!line! !#%%a#%%b!
  set/a coun+=#%%a#%%b
 )
 echo !line! !coun!
)
)>b.xls
start b.xlsCOPY