[文本处理] [已解决]把文本方块旋转的BAT代码错在哪里？

@echo off
setlocal enabledelayedexpansion
set m=0&set n=0
for /f %%a  in (1.txt) do (
   set /a m+=1
   for %%b in (%%a) do (
      set /a n+=1
      call set s%%!m!%%%%!n!%%=%%b      
   )
   set i=!n!
   set n=0
)
pause
for /l %%a in (1 1 %i%) do (
   for /l %%b in (1 1 %m%) do (
      set /p=!s%%b%%a! <nul
   )
   echo.
)
pause
 
复制代码

@echo off&setlocal enabledelayedexpansion
set m=0&set n=0
for /f "delims=" %%a  in (1.txt) do (
   set /a m+=1,n=0
   for %%b in (%%a) do (
      set /a n+=1
      set "$!m!_!n!=%%b"
   )
)

for /l %%a in (1 1 %n%) do (
   for /l %%b in (1 1 %m%) do (
      set /p=!$%%b_%%a! <nul
   )
   echo.
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt) do (
    set n=10000
    for %%b in (%%a) do (
       for %%c in (!n!) do (
           if defined #%%c (
               set "#%%c=!#%%c! %%b"
           ) else (
               set "#%%c=%%b"
           )
           set/a n+=1
       )
    )
)
(for /f "tokens=1* delims==" %%a in ('set #') do (
    echo,%%b
))>2.txt
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt) do (
    set n=0
    for %%b in (%%a) do (
       call set #!n!=%%#!n!%% %%b
       set /a n+=1
    )
)
for /f "tokens=1* delims==" %%a in ('set #') do echo,%%b
pause
复制代码

for /f "tokens=*" %%i in (" a b c  ")  do echo %%i
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt)do (
    set n=10000
    for %%b in (%%a)do (
        for %%c in (!n!)do set "#%%c=!#%%c! %%b"
        set/a n+=1
    )
)
(for /f "tokens=1* delims== " %%a in ('set #')do echo,%%b)
复制代码