【练习-015】批处理随机取值练习 - 出题挑战 - 批处理之家 BAT,CMD,批处理,PowerShell,VBS,DOS - Powered by Discuz!

批处理之家 » 出题挑战 » 【练习-015】批处理随机取值练习

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 8 Rank: 8

帖子: 2702
积分: 14562
技术: 177
捐助: 630
注册时间: 2008-6-16

16楼 跳转到 »

发表于 2008-8-26 12:09 | 只看该作者

下面给出本人的解：

@echo off&setlocal enabledelayedexpansion
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
     set /a n+=1,a=!random!%%2
     if !a! equ 0 (
        set "_!random!!random!!random!=%%i"
        ) else (
        set "_!random!!random!!random!=!n!"
     )
)
for /f "tokens=2 delims==" %%i in ('set _') do (
     set /a n-=1
     if !n! equ 15 pause>nul&goto :eof
     set /p=%%i <nul
)
复制代码

[ 本帖最后由 batman 于 2008-8-26 12:13 编辑 ]

2 评分人数

随风: 确实妙的很，赞！ + 1
more: 妙!!!PB + 10 技术 + 5

＊＊＊共同提高＊＊＊

Rank: 4

帖子: 38
积分: 425
技术: 0
捐助: 0
注册时间: 2008-7-30

17楼

发表于 2008-8-27 20:15 | 只看该作者

@echo off&setlocal enabledelayedexpansion
:jj
set aa=1
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
set !aa!=%%i &set /a aa=!aa!+1
) 
set va=1
:tj
set /a dd=%random%%%26+1 &set/a ss=%random%%%2
if %ss%==0 (set/p=%dd% <nul) else set/p=!%dd%! <nul
set/a va+=1 
if %va% lss 11 goto tj
pause>nul
复制代码

Rank: 8 Rank: 8

帖子: 2702
积分: 14562
技术: 177
捐助: 630
注册时间: 2008-6-16

18楼

发表于 2008-8-27 20:23 | 只看该作者

楼上没考虑重复的情况？

＊＊＊共同提高＊＊＊

Rank: 4

帖子: 38
积分: 425
技术: 0
捐助: 0
注册时间: 2008-7-30

19楼

发表于 2008-8-28 21:02 | 只看该作者

考虑后如下，但效率低

@echo off&setlocal enabledelayedexpansion
:jj
set aa=1 &set "bb="
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
set !aa!=%%i &set /a aa=!aa!+1
) 
set va=1
:tj
set /a dd=%random%%%26+1 &set/a ss=%random%%%2
echo %bb% |find "%dd: =%">nul 2>nul &&goto tj
set bb=%bb% %dd%
if %ss%==1 (set/p=%dd% <nul) else set/p=!%dd%! <nul
set/a va+=1
if %va% lss 11 goto tj
pause>nul
复制代码

Rank: 4

帖子: 38
积分: 425
技术: 0
捐助: 0
注册时间: 2008-7-30

20楼

发表于 2008-8-28 21:20 | 只看该作者

原帖由 batman 于 2008/8/26 12:09 发表
@echo off&setlocal enabledelayedexpansion
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
   set /a n+=1,a=!random!%%2
   if !a! equ 0 (
      set "_!random!!random!!ra ...

请问 set_ 是什么意思？还有那个 set "_!random!!random!!random!=%%i 呢？

Rank: 8 Rank: 8

帖子: 2702
积分: 14562
技术: 177
捐助: 630
注册时间: 2008-6-16

21楼

发表于 2008-8-29 00:51 | 只看该作者

原帖由 mkl 于 2008-8-28 21:20 发表

请问 set_ 是什么意思？还有那个 set "_!random!!random!!random!=%%i 呢？

请在我的代码的第一个for循环后加入一个set _运行看看，其实set _就是显示所有以_字符
打头的变量，具体可在cmd中键入set /?查询。

＊＊＊共同提高＊＊＊

Rank: 8 Rank: 8

帖子: 1759
积分: 5387
技术: 51
捐助: 210
注册时间: 2007-10-26

22楼

发表于 2008-8-30 18:32 | 只看该作者

16楼方法确实巧妙，不错。。！

技术问题请到论坛发帖求助！

Rank: 8 Rank: 8

帖子: 675
积分: 3226
技术: 75
捐助: 101
注册时间: 2009-4-10

23楼

发表于 2009-5-2 17:25 | 只看该作者

来一个规规矩矩的

取到一个剔除一个

@echo off&setlocal enabledelayedexpansion
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z "
for %%i in (%str%) do (set/a #+=1,%%i=#)
for /l %%a in (1,1,10) do (
    set/a asc=!random!%%#*2,#-=1
    for %%b in (!asc!) do (set asc=!str:~%%b,1!)
    for %%b in (!asc!) do (set str=!str:%%b =!&set/a $=!random!%%2,1/$ 2>nul||set asc=!%%b!)
    echo !asc!
)
pause
复制代码

Rank: 8 Rank: 8

帖子: 2702
积分: 14562
技术: 177
捐助: 630
注册时间: 2008-6-16

24楼

发表于 2009-5-2 20:01 | 只看该作者

楼上会存在效率问题，特别是用到了||管道符。

[ 本帖最后由 batman 于 2009-5-2 20:03 编辑 ]

＊＊＊共同提高＊＊＊

Rank: 8 Rank: 8

帖子: 675
积分: 3226
技术: 75
捐助: 101
注册时间: 2009-4-10

25楼

发表于 2009-5-2 23:31 | 只看该作者

测试了一下，“||”管道操作虽然要比其它管道操作快，但是比起if还是要慢好多，相当于if 用时的5~8倍。
改为用if 判断。综合测度速度不错。

@echo off&setlocal enabledelayedexpansion
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z "
for %%i in (%str%) do (set/a #+=1,%%i=#)
for /l %%a in (1,1,10) do (
    set/a asc=!random!%%#*2,#-=1
    for %%b in (!asc!) do (set asc=!str:~%%b,1!)
    for %%b in (!asc!) do (set str=!str:%%b =!&set/a $=!random!%%2&if !$! equ 0 set asc=!asc!)
    echo !asc!
)
pause
复制代码

Rank: 6 Rank: 6

帖子: 187
积分: 3145
技术: 4
捐助: 0
注册时间: 2008-10-30

26楼

发表于 2009-6-16 23:15 | 只看该作者

@echo off&setlocal enabledelayedexpansion
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%str%) do set/a n+=1&set "_!n!=!n! %%i"
:loop
set/a m=%random%%%26+1,n=%random%%%2+1
if not defined #%m% (
    for /f "tokens=1,2" %%1 in ("!_%m%!") do (
        <nul set/p=%%%n% &set/a num+=1,#%m%=0
     )
)
if %num% lss 10 goto loop
echo/&pause
复制代码