[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖
powerbat

Rank: 7Rank: 7Rank: 7

帖子
752 
积分
4553 
技术
139  
捐助
0  
注册时间
2010-8-24 
1楼 跳转到 » 倒序看帖
打印
tT
发表于 2012-3-7 21:15 | 只看该作者

[文件管理] 批处理将文件重命名为文件修改时间(精确到秒)

本帖最后由 powerbat 于 2012-3-7 22:41 编辑

支持拖放、支持子目录、支持设置要修改的文件类型（这些功能很简单，可自行添加代码），兼容特殊字符。
  1. @echo off &rem powerbat @ www.bathome.net 批处理之家 bat脚本

  2. set "type=jpg,png" &rem 文件类型

  3. set "folder=%~dp0." &rem 文件所在目录

  4. set "SubDir=0" &rem 是否包含子目录

  5. 

  6. wmic.exe /? >nul 2>&1 || (echo no wmic, exit& pause&exit/b)

  7. 

  8. if "%~1" neq "" set "folder=%~1"

  9. for %%a in ("%folder%") do set "FileD=%%~da" & set "FileP=%%~pnxa\"

  10. 

  11. goto skip

  12. rem 先重命名一次，加一段文件名中不会出现的字符串，以防可能的文件名重复问题。

  13. set "ext=%type%" & set "sub="

  14. if "%type%" neq "*" if "%type%" neq "*.*" set "ext=*.%type:,= *.%"

  15. if "%SubDir%" neq "0" set "sub=/s"

  16. for /f "delims=" %%a in ('dir /b %sub% %ext%') do (

  17.     ren "%%~fa" "powerbat@bathome_%%~nxa"

  18. )

  19. :skip

  20. 

  21. set "part=%FileP:\=\\%"

  22. set "part=%part:[=[[]%"

  23. set "part=%part:_=[_]%"

  24. setlocal enableDelayedExpansion

  25. set "part=!part:%%=[%%]!"

  26. endlocal& set "part=%part%"

  27. if "%type%" neq "*" if "%type%" neq "*.*" (

  28.     set "ext=and (extension='%type:,=' OR extension='%')"

  29. ) else set "ext="

  30. if "%SubDir%"=="0" (

  31.     set "Filter=drive='%FileD%' and path='%FileP:\=\\%' %ext%"

  32. ) else (

  33.     set "Filter=drive='%FileD%' and path LIKE '%part%%%' %ext%"

  34. )

  35. (set wmic=wmic.exe datafile where "%Filter%" get name^,LastModified)

  36. 

  37. for /f "tokens=1,3* delims=.+ " %%a in ('%%wmic%%') do (

  38.     set "t=%%a"

  39.     rem 用for过滤掉wmic结果中的不可见字符

  40.     for /f "delims=" %%i in ("%%c") do (

  41.         set "f=%%~fi"

  42.         set "p=%%~dpi"

  43.         set "n=%%~ni"

  44.         set "x=%%~xi"

  45.         setlocal enableDelayedExpansion

  46.         set "t=!t:~,4!-!t:~4,2!-!t:~6,2! !t:~8,2!.!t:~10,2!.!t:~12!"

  47.         if not exist "!p!!t!!x!" (

  48.             ren "!f!" "!t!!x!"

  49.         ) else  if "!t!" neq "!n!" (

  50.             set n=1

  51.             for %%u in ("!p!!t!_*!x!") do set /a n+=1

  52.             ren "!f!" "!t!_!n!!x!"

  53.         )

  54.         endlocal

  55.     )

  56. )

  57. pause
复制代码
批处理在特殊字符方面有天生缺陷，所以用批处理要做到兼容特殊字符就有点吃力，效率不怎么高。
重命名时要考虑到的一个重点是判断是否存在重复文件名，由于cmd没有while循环语句，要达到类似效果只能借助标签，但这样会进一步降低效率。
在兼顾效率的基础上，这是采用的方法是先将所有文件修改为别的名字，彻底排除重复的可能性。（默认没有开启，将goto skip去掉即可启用）。

（批处理做这种事真是弱暴了。。。但我不想用vbs，虽然我会）
1

评分人数

收藏 分享
script56
新加坡Google

powerbat

Rank: 7Rank: 7Rank: 7

帖子
752 
积分
4553 
技术
139  
捐助
0  
注册时间
2010-8-24 
2楼
发表于 2012-3-8 20:00 | 只看该作者
如果文件数量较多(如几千个)，wmic会出错：
代码 = 0x80020009
说明 = 发生意外。
设备 = Dispatch

有可能是wmic分配的内存不够用。
看来wmic也太矬了。。。
vbs版
http://www.bathome.net/thread-15803-1-1.html
script56
新加坡Google

TOP

lllsoslll

Rank: 2

帖子
97 
积分
164 
技术
6  
捐助
0  
注册时间
2011-3-29 
3楼
发表于 2012-4-15 18:12 | 只看该作者
某些情况下，同一时间内修改的文件，同一目录内可能很多；

如果有重命名，修改别的文件的名字，来给要命名的文件腾地方，若有快捷方式，或者文件之间存在关联性什么的，就被破坏了；

对程序来说，你只有修改你要访问的文件的权利，谁影响你的访问你就干掉谁，是流氓作风，

用这种方式如何？
201204151808[1].txt
201204151808[2].txt
...
SOS --- >> lllsoslll@163.com

TOP

Rocmind

Rank: 1

帖子
7 
积分
16 
技术
0  
捐助
0  
注册时间
2014-12-16 
4楼
发表于 2015-7-3 19:31 | 只看该作者
非常有用，好多摄像文件，每次皆是从1，2，3，开始命令，这个批处理完全解决了命名重复的问题

TOP

kimpppg

Rank: 1

帖子
13 
积分
26 
技术
0  
捐助
0  
注册时间
2021-1-9 
5楼
发表于 2024-6-4 15:24 | 只看该作者
重命名为创建时间是改哪一行。

TOP

Batcher

Rank: 12Rank: 12Rank: 12

帖子
14935 
积分
46142 
技术
857  
捐助
745  
注册时间
2008-6-9 
6楼
发表于 2024-6-4 15:46 | 只看该作者
回复 5# kimpppg


    第35行LastModified修改为CreationDate
1

评分人数

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

TOP

newswan

Rank: 5Rank: 5

帖子
1066 
积分
1453 
技术
103  
捐助
0  
注册时间
2010-6-20 
7楼
发表于 2024-6-4 17:34 | 只看该作者
本帖最后由 newswan 于 2024-6-4 18:50 编辑

powershell
  1. Param(

  2. 	[Parameter(ValueFromRemainingArguments)]

  3. 	[string[]]$Path

  4. )

  5. 

  6. if ([string]::IsNullOrEmpty($Path)) {

  7. 	$Path = "D:\Downloads"

  8. }

  9. $ext = "*.apk"

  10. $isRecurse = $False

  11. 

  12. 

  13. if ( $isRecurse ) {

  14. 	$command = { Get-ChildItem -Filter $ext -File -Recurse }

  15. } else {

  16. 	$command = { Get-ChildItem -Filter $ext -File }

  17. }

  18. 

  19. 

  20. $Path | Invoke-Command -ScriptBlock $command | ForEach-Object {

  21. 		write-host ( '' + $_.LastWriteTime + " : " + $_.FullName )

  22. 		Rename-Item -Path $_.FullName -NewName ( '' + $_.LastWriteTime.ToString("yyyy-MMdd-HHmmss") + $_.Extension )

  23. 	}
复制代码

TOP

返回列表