@echo off&setlocal enabledelayedexpansion
::@随风 @bbs.bathome.net @2009-04-18
for /f "delims=" %%a in (a.txt) do (
   set /a sun+=1,n=8189*2,max=1
   set s=%%a&set s=!s: =!&set "var="
   for /l %%a in (1 1 14) do (
      if defined var set /a n=var
      set /a n/=2
      for %%i in (!n!) do (
         if "!s:~%%i,1!"=="" (set /a var=n) else (
            set s=!s:~%%i!&set /a max+=%%i,var-=%%i
   )))  
   if !h! lss !max! set /a num=sun,h=max
)
echo 字符数最多的行为：!num!
echo 字符数为：!h!
pauseCOPY

 
@echo off&setlocal enabledelayedexpansion
set m=0
for /f "delims=" %%a in (a.txt) do (
    set "str=%%a"&set "str=!str: =!0"
    for %%b in (!m!) do (if "!str:~%%b,1!" neq "" call :sub "%%a")
)
echo 字符数是多的是%var%行，共有%m%个字符。
pause
goto :eof
 
:sub
set/a en=m+40
for /l %%a in (!m!,1,!en!) do (
 if "!str:~%%a,1!" equ "" (
  set/a n=%%a-1
  if !m! lss !n! set/a m=!n!,n=0&set "var=%~1"
  goto :eof
 )
)
set/a m=en
goto :subCOPY

@echo off&setlocal enabledelayedexpansion
set m=1
for /f "delims=" %%a in (a.txt) do (
    set "str=%%a"&set "str=!str: =!0"
    for %%b in (!m!) do (if "!str:~%%b,1!" neq "" call :sub "%%a")
)
set /a m-=1
echo 字符数是多的是%var%行，共有%m%个字符。
pause
goto :eof
 
:sub
set/a en=m+40
for /l %%a in (!m!,1,!en!) do (
        if "!str:~%%a,1!" equ "" (
                echo 较多: %~1
        set/a m=%%a&set "var=%~1"&goto :eof)
)
set/a m=en
goto :subCOPY

::  GetMaxCharText.cmd - 找出字符最多的文本行
::  qzwqzw - 2010-01-05
::
::  基本构思：
::      将原文本每行尾部加足够的一定数量的空格，在文本右侧形成一个不等齐空格区域
::      原文本行越长，其后的空格区域就越长，然后用sort /+n 仅对空格区域进行排序
::      因为区域内都是空格，则排序的依据就是空格的长度，也就是原行文本的长度
::
@echo off & setlocal EnableDelayedExpansion
set maxLineLen=80
set infile=%~sf0
for /l %%i in (1,1,%maxLineLen%) do set zone= !zone!
:: findstr 会忽略空行和仅含空格的行，但显示行号会跨过这些行，这是我们需要的特性
:: 将行号与行文本分别处理，是因为不对齐行号会影响行文本长度的判断
(for /f "tokens=1* delims=:" %%l in ('findstr /n /r /c:"[^ ]"  %infile%') do (
    set LineNo=         %%l
    set LineNo=!LineNo:~-10!
    set Line=%%m
    set Line=!Line: =!
    echo.!LineNo!:!Line!!zone!
))>%temp%\%~sn0~1.t~1
sort /r /+%maxLineLen% %temp%\%~sn0.t~1 > %temp%\%~sn0.t~2
set/p maxLine=< %temp%\%~sn0.t~2 >nul
::  已找到最多字符的行，以下是提取行号和原行文本，行长度因未要求而忽略
for /f "delims=: " %%i in ("%maxline%") do set maxLineIdx=%%i
::  使用find而不是findstr，是因为find够用够简单
set seekLine=find /v /n "" ^^^<%infile%^^^|find "[%maxLineIdx%]"
echo.字符最多的行第 %maxLineIdx% 行，内容为：
for /f "tokens=1* delims=[]" %%l in ('%seekLine%') do echo.%%m
for %%f in (%temp%\%~sn0.t*) do del %%fCOPY

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
     set /a t+=1
     set i=%%a
     set y!t!=!i!
     set i=!i: =!
     call:x !i!
     set /a n!t!=!num!
)
for /l %%b in (1 1 !t!) do (
if !n%%b! lss !number! (
 set /a n%%b=number
 set y%%b=!str!
)
set /a number=n%%b
set str=!y%%b!
cls
echo 字符数最多的行是：!y%%b!共有字符：!n%%b! 个
)
pause>nul&exit
:x
    set i=%1
    set num=
:loop
     set i=!i:~1!
     set /a num+=1
     if "!i!"==""  ( echo abc >nul
     )  else ( goto:loop)COPY

@echo off&setlocal enabledelayedexpansion
set /a $=11,n=4096
for /l %%a in (-2 1) do set $=!$!!$!!$!!$!
(copy a.txt %$%$&findstr .* %$%?>$
for %%a in (2048 1024 512 256 128 64 32 16 8 4 2 1) do sort /+100 /rec !n! $&&set /a n-=%%a,h=n-130||set /a n+=%%a)>nul 2>nul
for /f "delims=" %%a in ('sort /+%h% a.txt') do set long=%%a
echo !long!
del /f /q *$&pauseCOPY

@echo off&setlocal enabledelayedexpansion
set n=32768
(for %%a in (16384 8192 4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do sort /+100 /rec !n! 1.txt&&set /a n-=%%a||set /a n+=%%a)>nul 2>nul
::很像plp兄曾转发过的折半回溯法求字符长度的函数吧？是的，这里就是对那个思路的改造，只不过我是利用sort /rec超过最长行字数时会出错的特性来进行运算的。
echo 最长行有%n%个字符
pauseCOPY

@echo off&setlocal enabledelayedexpansion
set /a tmp=11,n=4096
::此处的tmp是用于补位的，设成任意两个字符都行，为了压缩代码，把它设成十位数
for /l %%a in (1 1 3) do set tmp=!tmp!!tmp!!tmp!!tmp!
::将tmp补足128位
copy>nul a.txt %tmp:~2%$
::将a.txt保存到一个文件名长度为127个字符的临时文件中
findstr .* %tmp:~2%?>$
::用findstr命令配合通配符实现补位，127个字符长的文件名加上“:”号，刚好128个字符，将结果输出到临时文件中
for %%a in (2048 1024 512 256 128 64 32 16 8 4 2 1) do (
   sort /+100 /rec !n! $&&set /a n-=%%a,h=n-128||set /a n+=%%a
)>nul 2>nul
::用sort /rec判断该临时文件最长行的长度
for /f "delims=" %%a in ('sort /+%h% a.txt') do set long=%%a
::因为知道了最长行的长度，所以可以直接用sort /+n来精确排序，通过for命令，很容易获得最后一行的内容(用set /p也可以，但是考虑到变量长度，还是用for保险，当然用findstr取指定行也是一个不错的选择)。
echo !long!
::不解释
del /f /q *$
::删除临时文件，销赃
pauseCOPY

endlocal
for /f "tokens=1* delims=:" %%a in ('findstr /n a.txt^|findstr 1:') do set "long=%%b"
...COPY