[文本处理] 批处理怎样截取txt文本随机行中以标点符号分割的字符数少于指定数值的随机字段？

@echo off
set "str=如豆的煤油灯盏中，我度过了几年的学习时光，如水的童年也悄然逝去。哥哥到外地读书去了，我和妹妹也在镇里的一所中学读书。"
set str=%str:，=,%
set str=%str:。=,%
setlocal enabledelayedexpansion
for %%i in (%str%) do (
    set str=%%i
    if "!str:~13,1!" equ "" (
       set/a n+=1
       set _!n!=%%i
    )
)
set/a n=%random%%%n+1
echo !_%n%!
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set/p "file_path=[请拖入要改标题的文件]"
for /f "usebackq tokens=1 delims=，。； " %%a  in (%file_path%) do (
  set "string=%%a"
)
if "%string:~14,1%"=="" (echo 标题:[%string%]) else (echo 标题不符合规定) 
pause
复制代码

@echo off
SetLocal EnableDelayedExpansion

for %%f in (*.txt) do call :sub "%%f"
echo 完成。按任意键退出...
pause >nul
exit /b

:sub
rem 计算文件行数
set n=
for /f "usebackq" %%a in ("%~1") do set /a n += 1

:retry
rem 随机提取一行
set /a skip_num = %random% %% n
if "%skip_num%" neq "0" (set skip=skip=%skip_num%) else set skip=
for /f "usebackq %skip% tokens=*" %%a in ("%~1") do (
    set str=%%a
    goto next
)

:next
rem 从一行中随机选一段
set "str=%str:"=%"
for %%a in ("\" "/" ":" "<" ">" "|") do set str=!str:%%~a=!
set "str=%str:?=%"
set "str=%str:，=" "%"
set "str=%str:。=" "%"
set .n=
for %%a in ("%str%") do (
    if "%%~a" neq "" (
        set NewName=%%~a
        if "!NewName:~13!"=="" (
            set /a .n += 1
            set !.n!=%%~a
        )
    )
)
if not defined .n goto retry

set /a ran = %random% %% .n + 1
ren "%~1" "!%ran%!.*" 2>nul || goto retry
goto :eof
复制代码