[文本处理] 批处理怎么实现按指定符号分割TXT文本呢？

@echo off&setlocal enableDelayedExpansion
for %%a in (*.txt) do set n=%%~na
copy "%n%.txt" temp.h>nul
fr.exe temp.h /ric:"。" /t:"。\r\n"
for /f "delims=" %%a in (temp.h) do (
	set/a a+=1
	>"%n%_!a!.txt" echo %%a
)
del temp.h
复制代码

@echo off
set "文本=1.txt"
set "分隔符=。"

findstr /n .* "%文本%" >.tmp
set n=1
for /f "delims=" %%a in (.tmp) do (
    set var=%%a
    SetLocal EnableDelayedExpansion
    set var=!var:*:=!
    if "!var!" neq "" (
        if "!var:%分隔符%=!" neq "!var!" (
            set var=!var:?=？!
            set var=!var:"=”!
            for %%b in ("!var:%分隔符%=" "!") do (
                >.tmp echo !n!
                EndLocal
                set var=%%~b
                set /a n += 1
                set /p m=<.tmp
                SetLocal EnableDelayedExpansion
                set var=!var:？=?!
                >>"!文本:~0,-4!_!m!.txt" echo,!var:”="!
            )
        ) else >>"!文本:~0,-4!_!n!.txt" echo,!var!
    ) else >>"!文本:~0,-4!_!n!.txt" echo,!var!
    EndLocal
)

del .tmp
复制代码

@echo off
set "分隔符=。"

for /f "delims=" %%a in ('dir /a:-d /b *.txt') do (
    findstr /n .* "%%a" >.tmp
    set fname=%%~na
    set fext=%%~xa
    set n=1
    for /f "delims=" %%a in (.tmp) do (
        set var=%%a
        SetLocal EnableDelayedExpansion
        set var=!var:*:=!
        if "!var!" neq "" (
            if "!var:%分隔符%=!" neq "!var!" (
                set var=!var:?=？!
                set var=!var:"=”!
                for %%b in ("!var:%分隔符%=%分隔符%" "!") do (
                    if %%b neq "" (
                        >.tmp echo !n!
                        EndLocal
                        set var=%%~b
                        set /a n += 1
                        set /p m=<.tmp
                        SetLocal EnableDelayedExpansion
                        set var=!var:？=?!
                        >>"!fname!_!m!!fext!" echo,!var:”="!
                    )
                )
            ) else >>"!fname!_!n!!fext!" echo,!var!
        ) else >>"!fname!_!n!!fext!" echo,!var!
        EndLocal
    )
)

del .tmp
复制代码