返回列表 发帖
大地

Rank: 2

帖子
121 
积分
189 
技术
0  
捐助
0  
注册时间
2019-2-18 
1楼 跳转到 » 倒序看帖
打印
tT
发表于 2025-3-29 20:26 | 只看该作者

[文本处理] 【已解决】批处理查找文件夹路径并替换注册表文件内路径？

本帖最后由 大地 于 2025-4-8 07:34 编辑

查找文件夹路径并替换注册表文件内路径

以下码在XP系统中能运行，本以为正确了，改成已解决，后发现在在win10中出错，无法运行，汗颜！！所以重新提交求助，望大神邦忙，感 谢。


批处理通过所有分区深层子目录中搜索，查到第一个文件夹PETOOLS后中止搜索，并把注册表1.reg中原有的路径C:\\PETOOLS替换为新的路径，注意：注册表路径是双斜杠\\,，单斜杠是无法导入注册表的，路径中没有空格也没特殊字符，也不需要搜索分区根目录，只要子目录，不要用wmic 也不要用poseerhsell 批处理代码如何写？

以下是代码在XP中能运行，在win10中出错：

@echo off
setlocal enabledelayedexpansion

set "target=PETOOLS"
set "regfile=1.reg"
set "found="

rem 遍历所有分区（C到Z）
for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%d:\ (
        echo 正在搜索 %%d 盘...
        rem 搜索子目录（排除根目录）
        for /f "delims=" %%a in ('dir /s /b /ad %%d:\%target% 2^>nul') do (
            set "path=%%a"
            rem 验证是否为子目录（路径包含两级以上目录）
            if not "%%~dpa"=="%%d:\" (
                rem 转义路径中的单斜杠为双斜杠
                set "newpath=!path:\=\\!"
                set "found=!newpath!"
                goto replace
            )
        )
    )
)

:replace
if defined found (
    echo 替换目标路径为: %found%
    rem 创建临时文件并写入替换后的内容
    (
        for /f "usebackq delims=" %%i in ("%regfile%") do (
            set "line=%%i"
            set "line=!line:C:\\PETOOLS=%found%!"
            echo !line!
        )
    ) > "%regfile%.tmp.reg"

    rem 替换原文件
    move /y "%regfile%.tmp.reg" "%regfile%" > nul
    echo SUCCESS
) else (
    echo FAILED
)

endlocal
pause
收藏 分享

Five66

Rank: 5Rank: 5

帖子
1017 
积分
1446 
技术
150  
捐助
0  
注册时间
2021-8-26 
2楼
发表于 2025-3-29 21:07 | 只看该作者
move /y "%regfile%.tmp""%regfile%">nul
参数那里连在一起了??? 分开来???

TOP

大地

Rank: 2

帖子
121 
积分
189 
技术
0  
捐助
0  
注册时间
2019-2-18 
3楼
发表于 2025-3-29 21:31 | 只看该作者
回复 2# Five66
分开后   测试也不行     应该不是这个问题

TOP

Five66

Rank: 5Rank: 5

帖子
1017 
积分
1446 
技术
150  
捐助
0  
注册时间
2021-8-26 
4楼
发表于 2025-3-29 21:39 | 只看该作者
回复 3# 大地


    把运行后的结果发出来看看

TOP

大地

Rank: 2

帖子
121 
积分
189 
技术
0  
捐助
0  
注册时间
2019-2-18 
5楼
发表于 2025-3-29 21:46 | 只看该作者
本帖最后由 大地 于 2025-3-29 21:51 编辑

回复 4# Five66 但
显示运行成功，但1.reg内容如下了：


F:\rr>(
set "line=C:\\PETOOLS"  
set "line=!line:C:\\PETOOLS=F:\\rr\\kkkk\\PETOOLS!"  
echo !line!
)
F:\\rr\\kkkk\\PETOOLS

多了上面5行
原来的C:\\PETOOLS  变为  F:\\rr\\kkkk\\PETOOLS  是对的  就是多了上面5行

TOP

Five66

Rank: 5Rank: 5

帖子
1017 
积分
1446 
技术
150  
捐助
0  
注册时间
2021-8-26 
6楼
发表于 2025-3-29 22:03 | 只看该作者
回复 5# 大地


    1.reg编码是啥???

TOP

大地

Rank: 2

帖子
121 
积分
189 
技术
0  
捐助
0  
注册时间
2019-2-18 
7楼
发表于 2025-3-29 22:05 | 只看该作者
回复 6# Five66

ANSI

TOP

Five66

Rank: 5Rank: 5

帖子
1017 
积分
1446 
技术
150  
捐助
0  
注册时间
2021-8-26 
8楼
发表于 2025-3-29 22:34 | 只看该作者
回复 7# 大地


    啊? ,开头不加上@echo off的??

TOP

窄口牛

Rank: 5Rank: 5

帖子
291 
积分
516 
技术
10  
捐助
0  
注册时间
2008-2-16 
9楼
发表于 2025-3-30 08:44 | 只看该作者
pecmd脚本直接搞不出来？

TOP

大地

Rank: 2

帖子
121 
积分
189 
技术
0  
捐助
0  
注册时间
2019-2-18 
10楼
发表于 2025-4-5 16:16 | 只看该作者
追加求助，....

TOP

77七

Rank: 6Rank: 6

帖子
1797 
积分
2951 
技术
364  
捐助
50  
注册时间
2022-9-18 
11楼
发表于 2025-4-5 17:13 | 只看该作者
应该是查找文件夹的姿势不对，不是系统差异，是文件夹位置差异

@echo off
cd /d "%~dp0"
set "target=PETOOLS"
set "regfile=1.reg"
set "found="
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
	if exist "%%a:\" (
		for /f "delims=" %%d in ('dir /b /s /ad "%%a:\%target%?"') do (
			if /i "%%~nxd" equ "%target%" (
				if /i "%%d" neq "%%a:\%target%" (
					set found=%%d
					call set "found=%%found:\=\\%%"
					goto :replace
				)
			)
		)
	)
)
:replace
if defined found (
	(for /f "delims=" %%a in ('find /n /v "" ^< "%regfile%"') do (
		set str=%%a
		setlocal enabledelayedexpansion
		set "str=!str:C:\\PETOOLS=%found%!"
		echo=!str:*]=!
		endlocal
	)) > #
	move # "%regfile%"
	echo SUCCESS
) else (
	echo FAILED
)
pauseCOPY
bat小白，请多指教！谢谢！

TOP

aloha20200628

Rank: 6Rank: 6

帖子
1238 
积分
2125 
技术
289  
捐助
0  
注册时间
2021-10-13 
12楼
发表于 2025-4-5 19:01 | 只看该作者
本帖最后由 aloha20200628 于 2025-4-5 19:19 编辑

回复 1# 大地

忽略 C 盘，从 D 盘开始遍历盘符...
@echo off &echo,正在处理...&setlocal enabledelayedexpansion &for %%D in (
	D E F G H I J K L M N O P Q R S T U V W X Y Z
) do if exist "%%D:\" for /f "delims=" %%d in ('dir /b/s/ad %%D:\PETOOLS 2^>nul') do (
  set "d=%%d" &set "d=!d:\=\\!"
  (for /f "delims=" %%a in (1.reg) do (
      set "a=%%a" &if /i "!a!"=="!a:c:\\PETOOLS=!" (echo,%%a) else (
      set "ok=1" &for %%x in ("!d!") do echo,!a:c:\\PETOOLS=%%~x!)
  ))>#.#
  (if !ok! equ 1 move /y #.# 1.reg) &goto:[end]
)
:[end]
pause&exit/bCOPY

TOP

大地

Rank: 2

帖子
121 
积分
189 
技术
0  
捐助
0  
注册时间
2019-2-18 
13楼
发表于 2025-4-8 07:05 | 只看该作者
回复 11# 77七


    测试成功，谢谢大佬！

TOP

大地

Rank: 2

帖子
121 
积分
189 
技术
0  
捐助
0  
注册时间
2019-2-18 
14楼
发表于 2025-4-8 07:06 | 只看该作者
回复 12# aloha20200628


    测试成功，谢谢大佬！！！

TOP

返回列表