[其他] 【已解决】批处理怎样随机获取指定目录图片的完整路径（含后缀）？谢谢

Rank: 5 Rank: 5

帖子: 938
积分: 1335
技术: 139
捐助: 0
注册时间: 2021-8-26

2楼

发表于 2025-1-27 09:28 | 只看该作者

请确保文件夹内都是图片文件
文件夹图片数量32767以内
不包括子文件
不包括隐藏文件
图片文件名不能包含英文感叹号等特殊字符

//

 @echo off&setlocal
 
set "_@@path=D:\123"
 
setlocal enabledelayedexpansion
for %%i in ("%_@@path%\*") do (
set /a @@n+=1
set /a @@r=32767/@@n+1
if !random! lss !@@r! set "_@randomfile=%%i"
)
echo,!_@randomfile!&endlocal
endlocal&pause&exit/bCOPY

1 评分人数

yyz219: 乐于助人技术 + 1

Rank: 5 Rank: 5

帖子: 807
积分: 1042
技术: 4
捐助: 0
注册时间: 2021-8-30

3楼

发表于 2025-1-27 09:32 | 只看该作者

回复 2# Five66

我试一试先谢谢

我是小白，希望老师多多帮助

aloha20200628

少校

Rank: 6 Rank: 6

帖子: 1134
积分: 1920
技术: 256
捐助: 0
注册时间: 2021-10-13

4楼

发表于 2025-1-27 09:40 | 只看该作者

本帖最后由 aloha20200628 于 2025-1-27 10:33 编辑

回复 1# yyz219

先获取当前目录中图片文件总数n，再从1-n之间随机抽取一个对应dir文件列表的行号 r …

 @echo off &setlocal
cd /d "d:\123" &dir /b/a-d *.jpg>#
for /f %%n in ('find /c /v ""^<#') do (set "n=%%n")
set/a "r=1+%random%%%%n%"
(for /l %%k in (1,1,%r%) do set/p "jF=")<#
echo,随机抽取序号=%r% 》%jF%
del /q "#"&pause&exit/bCOPY

1 评分人数

yyz219: 乐于助人技术 + 1

Rank: 5 Rank: 5

帖子: 807
积分: 1042
技术: 4
捐助: 0
注册时间: 2021-8-30

5楼

发表于 2025-1-27 12:00 | 只看该作者

2楼、4楼都可以
4楼————特殊字符也行

我是小白，希望老师多多帮助

Rank: 5 Rank: 5

帖子: 807
积分: 1042
技术: 4
捐助: 0
注册时间: 2021-8-30

6楼

发表于 2025-1-27 12:39 | 只看该作者

回复 4# aloha20200628

怎样增加其它格式（比如.png）的图片？谢谢

我是小白，希望老师多多帮助

Rank: 5 Rank: 5

帖子: 807
积分: 1042
技术: 4
捐助: 0
注册时间: 2021-8-30

7楼

发表于 2025-1-27 12:46 | 只看该作者

回复 6# yyz219

解决了：
@echo off &setlocal
cd /d "D:\!123" &dir /b/a-d *.jpg *.png>#
for /f %%n in ('find /c /v ""^<#') do (set "n=%%n")
set/a "r=1+%random%%%%n%"
(for /l %%k in (1,1,%r%) do set/p "jF=")<#

set "随机=%jF%"
pecmd.exe wall %随机%
del /q "#"&exit/b

我是小白，希望老师多多帮助

ygqiang

中尉

Rank: 5 Rank: 5

帖子: 1338
积分: 799
技术: 15
捐助: 50
注册时间: 2010-4-18

8楼

发表于 2025-1-27 14:14 | 只看该作者

本帖最后由 ygqiang 于 2025-1-27 14:26 编辑

回复 7# yyz219

目录下好几个jpg图片，每次执行都可以随机获取到其中一张照片。

但是：
pecmd.exe wall %随机%

这个命令，win10系统下，执行后，桌面背景变成纯黑的了。
重复运行，一直这样。
对随机获取到的照片格式，有什么要求吗？

好像系统的操作逻辑是：
原图片转码后，生成新图片，再设为桌面背景

Five66

Rank: 5 Rank: 5

帖子: 938
积分: 1335
技术: 139
捐助: 0
注册时间: 2021-8-26

9楼

发表于 2025-1-27 14:20 | 只看该作者

回复 7# yyz219

说一下
for...*(2楼)或dir(4楼)的输出是有序的 ,直接使用时其实不怎么随机...
输出到文件时 , 当前代码页无法表示的字符会变成?号(例如文件名包含♪ ♥等字符) , 使用该文件时内容作为路径时可能会出错(可能包含了?号)

1 评分人数

77七: 感谢分享技术 + 1

Rank: 5 Rank: 5

帖子: 807
积分: 1042
技术: 4
捐助: 0
注册时间: 2021-8-30

10楼

发表于 2025-1-27 14:34 | 只看该作者

回复 8# ygqiang

你的系统里必须有pecmd.exe（没有的话，在PE中复制一个过去）

我是小白，希望老师多多帮助

ygqiang

中尉

Rank: 5 Rank: 5

帖子: 1338
积分: 799
技术: 15
捐助: 50
注册时间: 2010-4-18

11楼

发表于 2025-1-27 15:27 | 只看该作者

回复 10# yyz219

这个都有的。

Rank: 5 Rank: 5

帖子: 807
积分: 1042
技术: 4
捐助: 0
注册时间: 2021-8-30

12楼

发表于 2025-1-28 21:09 | 只看该作者

回复 4# aloha20200628
能不能弄成不需要文件 # ？

谢谢

我是小白，希望老师多多帮助

Five66

Rank: 5 Rank: 5

帖子: 938
积分: 1335
技术: 139
捐助: 0
注册时间: 2021-8-26

13楼

发表于 2025-1-28 22:42 | 只看该作者

2楼的改了下 , 应该支持特殊字符了

 @echo off&rem {
setlocal
 
set "_@@path=D:\123"
rem 全部是图片的话"%_@@path%\*"更省事 //
for %%i in ("%_@@path%\*.jpg" "%_@@path%\*.png") do (
set /a @@n+=1
set /a @@r=32767/@@n+1
setlocal enabledelayedexpansion
if !random! lss !@@r! (
endlocal
set "_@randomfile=%%i"
) else endlocal
)
for %%i in ("%_@randomfile%") do echo,%%~i
endlocal&rem     }
pause&exit/bCOPY

aloha20200628

少校

Rank: 6 Rank: 6

帖子: 1134
积分: 1920
技术: 256
捐助: 0
注册时间: 2021-10-13

14楼

发表于 2025-1-28 23:17 | 只看该作者

回复 12# yyz219

4楼代码是出于运行效率的考虑而采用临时文件，否则当目录中图片文件过千上万+，造成大数据循环操作都挤在 for ... ('命令管道') 的 ‘管道’ 里而导致明显降速甚至滞塞...
以下代码是针对小数据实况不用临时文件的版本

 @echo off &setlocal &cd /d "d:\123"
for /f %%n in ('dir /b/a-d *.jpg *.png^|find /c /v "" ') do (set "n=%%n")
set/a "r=1+%random%%%%n%"
for /f "tokens=1* delims=]" %%a in ('dir /b/a-d *.jpg *.png^|find /n /v ""^|find "[%r%]" ') do set "jF=%%b" 
echo,随机抽取序号=%r% 》%jF%
pause&exit/bCOPY

1 评分人数

yyz219: 乐于助人技术 + 1

Rank: 5 Rank: 5

帖子: 807
积分: 1042
技术: 4
捐助: 0
注册时间: 2021-8-30

15楼

发表于 2025-1-29 07:08 | 只看该作者

回复 14# aloha20200628

我试一试谢谢

我是小白，希望老师多多帮助