[文本处理] 【已解决】求助批处理从一堆XML中提取关键词写到csv中

@echo off
setlocal enabledelayedexpansion
set BoxHead=classId	skillName	skillId	skillLevel	getLevel	levelUpSp
for %%i in (%BoxHead%) do set %%i=true
echo,%BoxHead%
for /f "delims=" %%i in ('findstr "skill" *.xml') do (
    set n=
    set NewLine=!classId!
    for %%j in (%%i) do (
        if /i "!str!"=="classId" (
            set NewLine=%%~j
            set classId=%%~j
        ) else if defined !str! (
            set NewLine=!NewLine!	%%~j
            set n=1
        )
        set "str=%%~j"
    )
    if defined n (
        echo,!NewLine!
        set NewLine=
    )
)
pause
复制代码

@echo off &setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.xml') do (
	(set "v="&echo classID, skillName, skillId, skillLevel, getLevel, levelUpSp
	for /f tokens^=1-10^ delims^=^	^=^<^" %%a in (' findstr "=" "%%i" ') do (
		if /i "%%a"=="skillTree type" (set "v1=%%d")
		if /i "%%a"=="skill skillName" (
			set "v=!v1!, %%b, %%d, %%f, %%h"
			if /i "%%j" neq "true" (echo !v!, %%j) else echo !v!
		)
	))>%%~ni.csv
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
set BoxHead=classId,skillName,skillId,skillLevel,getLevel,levelUpSp
for %%i in (%BoxHead%) do set %%i=true
(echo,%BoxHead%
for /f "delims=" %%i in ('findstr "skill" *.xml') do (
    for %%j in (%%i) do (
        if /i "!str!"=="classId" (
            set classId=%%~j
        ) else if defined !str! (
            set NewLine=!NewLine!,%%~j
        )
        set "str=%%~j"
    )
    if defined NewLine (
        echo,!classId!!NewLine!
        set NewLine=
    )
))>out.csv
pause
复制代码

@echo off &(echo,classID	skillName	skillId	skillLevel	getLevel	levelUpSp
for %%F in (*.xml) do for /f tokens^=1-10^delims^=^" %%a in ('findstr /ic:" skillname=" "%%F" ') do (
    set/p="96	%%b	%%d	%%f	%%h"<nul
    if /i "%%j" neq "true" (echo,	%%j) else (echo,)
))>all.csv
pause&exit/b
复制代码

@echo off
cd /d "%~dp0"
set list=classId skillName skillId skillLevel getLevel levelUpSp
set "_list=%list:* =%"
(
	echo %list: =,%
	setlocal enabledelayedexpansion
	for /f "tokens=1* delims=:" %%i in ('findstr /i "%list: == %" *.xml') do (
		set str=%%j
		set "str=!str:/=!"
		set "str=!str:<=!"
		set "str=!str:>=!"
		for %%a in (%_list%) do (
			set _%%a=,
		)
		set _str=
		for %%a in (!str!) do (
			if "%%a" equ "%%~a" (
				set b=%%a
			) else (
				set _!b!=%%a
			)
		)
		for %%a in (%_list%) do (
			set _str=!_str!,!_%%a!
		)
		if "!_str:,=!" neq "" (
			echo !_classId!,!_str:~1!
		)
	)
	endlocal
) > out.csv
pause
exit
复制代码

@echo off
setlocal enabledelayedexpansion
for %%i in (a="1" b="2" c="3") do (
    echo,!str!
    echo,%%~i
    if /i "!str!"=="b" (
        set b=%%~i
        echo,*********  b=%%~i
    )
    echo,---------------------
    echo,
    set "str=%%~i"
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,9) do (
    set str=!str!,%%i
    echo,!str!
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,5) do (
    echo,!str!
    set str=%%i
    echo,!str!
    echo,-------------
    echo,
)
pause
复制代码

@echo off
set BoxHead=classId,skillName,skillId,skillLevel,getLevel,levelUpSp
for %%i in (%BoxHead%) do set _%%i=true
echo,%BoxHead%
for /f "tokens=2* delims=:	 " %%i in ('findstr /i "<skill" *.xml') do (
    if /i "%%i"=="<skillTree" (
        for %%k in (%%j) do (
            if defined n set "classId=%%~k"&set n=
            if "%%k"=="classId" set n=1
        )
    ) else (
        setlocal enabledelayedexpansion
        for %%k in (%%j) do (
            if defined _!str! set !str!=%%~k&set m=1
            set str=%%k
        )
        if defined m echo,!classId!,!skillName!,!skillId!,!skillLevel!,!getLevel!,!levelUpSp!&set m=
        endlocal
    )
)
pause
复制代码