[文件操作] 移动当天文件夹和文件到当天日期文件夹的bat代码怎么写？

@echo off
cd /d "%~dp0"
@REM 把当前目录下 创建日期是今天的文件和文件夹移动到 今天'yyyy-MM-dd'文件夹
set "batchfile=%~f0"
powershell -c "$today=[datetime]::Today;$di=[io.directory]::CreateDirectory($today.ToString('yyyy-MM-dd'));gci|where{$_.CreationTime.Date -eq $today -and $_.FullName -ne $di.FullName -and $_.FullName -ne $env:batchfile}|Move-Item -Destination ($di.FullName) -Verbose"
pauseCOPY

@echo off &md "..\%date:~,10%" 2>nul
(for /f "tokens=3* delims= " %%a in ('dir /tc/o-d^|findstr /bc:"%date:~,10% " ') do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "..\%date:~,10%\") 2>nul
pause&exit/bCOPY

@echo off &setlocal &set "td=%date:/=-%"
md "..\%td:~0,10%" 2>nul
(for /f "tokens=3* delims= " %%a in ('dir /tc/o-d^|findstr /bc:"%td:~0,10% " ') do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "..\%td:~0,10%\") 2>nul
endlocal&pause&exit/bCOPY

@echo off
cd /d "%~dp0"
for /f %%a in ('wmic os get localdatetime ^| findstr [0-9]') do (
	set d=%%a
)
for /f "tokens=1-3*" %%a in ('dir /tc ^| findstr /rive /c:"\." /c:"\.bat" /c:"\.cmd"') do (
	if "%%a" equ "%d:~0,4%/%d:~4,2%/%d:~6,2%" (
		if "%%d" neq "%d:~0,4%-%d:~4,2%-%d:~6,2%" (
			if exist "%%d\" (
				robocopy "%%d" "%d:~0,4%-%d:~4,2%-%d:~6,2%/%%d" /e /move
			) else (
				robocopy . "%d:~0,4%-%d:~4,2%-%d:~6,2%" "%%d" /mov
			)
		)
	)
)
pauseCOPY

谢谢10,11楼提醒
若楼主 dir 列表显示的时间格式如11楼所示 2024/09/06 周五 .... 则8楼代码须订正如下，其实就是多了一个 ‘周五’ 的字段

@echo off &setlocal &set "td=%date:/=-%"
md "..\%td:~0,10%" 2>nul
(for /f "tokens=4* delims= " %%a in ('dir /tc/o-d^|findstr /bc:"%date:~0,10% " ') do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "..\%td:~0,10%\") 2>nul
endlocal&pause&exit/bCOPY

@echo off &setlocal &set "td=%date:/=-%"
cd /d "d:\目标文件夹" &set "td=d:\目的地文件夹\%td:~0,10%"
md "%td%" 2>nul &set "tf=%td%\all.tmp"
dir /tc/o-d|findstr /bc:"%date:~0,10% ">"%tf%" &set/p s=<"%tf%" 
if "%s:~14,1%"==":" (set "q=3") else (set "q=4")
(for /f "tokens=%q%* delims= " %%a in (%tf%) do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "%td%\")>nul 2>nul
del /q "%tf%"&endlocal&pause&exit/bCOPY