[文件操作] 求助BAT脚本批量压缩文件

@echo off
rem 保存为ansi
rem 代码使用winrar\下的rar.exe，使用需添加到系统环境变量，或者写明绝对路径
cd /d "%~dp0"
set pwd=QWEasd
set f1=D:\实例_20240731_151654\A
set f2=D:\实例_20240731_151654\C
set log=d:\1.txt

md "%f2%" 2>nul
pushd "%f1%"
call :getdt d
(for /d %%d in (*) do (
	pushd "%%d"
	for /f "delims=" %%a in ('forfiles /s /m * /c "cmd /c if @isdir equ FALSE echo @relpath"') do (
		call :getdt
		set /p="%%~dpa,%%~nxa,"<nul
		rar a "%f2%\%%d.zip" -p%d%%pwd% "%%~a" 1>nul 2>nul
		if errorlevel 1 (
			echo 压缩失败
		) else (
			echo 压缩成功
		)
	)
	popd
))>>"%log%"
pause
exit

	:getdt
	for /f %%a in ('wmic os get localdatetime ^|findstr [0-9]') do (
		set t=%%a
	)
	if "%~1" equ "d" (
		set %~1=%t:~0,4%%t:~4,2%%t:~6,2%
	) else (
		set /p="%t:~0,4%年%t:~4,2%月%t:~6,2%日%t:~8,2%时%t:~10,2%分%t:~12,2%秒,"<nul
	)
	exit /b
复制代码

@echo off
set "input=D:\我的文档\桌面\批量压缩文件\实例\A"
set "output=D:\我的文档\桌面\批量压缩文件\实例\B"
rem 采用7zip压缩，请修改为实际路径
set "exe=D:\实际路径\7-Zip\7z.exe"
set "pwd=20240731QWEasd"
pushd %input%
(for /d %%d in (*) do (
	"%exe%" a -p%pwd% -t7z "%output%\%%d.7z" ".\%%d\*" >nul 2>nul
	if errorlevel 1 (
			echo %DATE% %TIME% %%~fd --- 压缩失败
		) else (
			echo %DATE% %TIME% %%~fd --- 压缩成功
		)
	
))>%~dp0LOG.txt
popd
start "" LOG.txt
exit/b
复制代码

@echo off &for %%F in ("abc.zip" "123.rar") do (
	rar.exe x %%F 2>nul >nul
	if errorlevel 0 (echo,解压成功) else echo,解压失败
)
pause&exit/b
复制代码

if errorlevel 0 (echo,解压成功) else echo,解压失败
复制代码

echo,解压成功
复制代码

if not errorlevel 1 (echo,解压成功) else echo,解压失败
复制代码

@echo off
call :1 -1
if errorlevel 0 (
	echo a
) else (
	echo b
)
pause
exit
	:1
	exit /b %~1
复制代码