[文件操作] 批处理统计文件夹内的图片视频，如何统计数量时排除一些文件，统计大小时包括这些文件

@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do (
    set/a p=v=z=0
    pushd "%%a"
    for %%b in (*.jpg *.png *.bmp) do (
        rem 计算放在这里，就是对所有图片大小的计算
        set/a z+=%%~zb
        if not "%%~nb"=="000" if not "%%~nb"=="00.1" if not "%%~nb"=="00.2" if not "%%~nb"=="00.3" (
            set/a p+=1
        )
    )
    for %%c in (*.mp4 *.avi *.mov *.mkv) do (
        set/a v+=1,z+=%%~zc
    )
    set/a "z>>=20"
    popd
    ren "%%a" "%%a [!p!P!v!V-!z!M]"
)
pause
复制代码

@echo off
rem 保存为ansi编码
cd /d "%~dp0"
for %%a in ("000" "00.1" "00.2" "00.3") do (
	set _"%%~a"=1
)
for /f "delims=" %%d in ('dir /b /ad') do (
	set /a p=v=z=0
	pushd "%%d"
	for /f "delims=" %%i in ('2^>nul dir /b /a-d *.jpg *.png *.bmp') do (
		if not defined _"%%~ni" (
			set /a p+=1
		)
	)
	for /f %%i in ('2^>nul dir /b /a-d *.mp4 *.avi *.mov *.mkv ^|find /c /v ""') do (
		set v=%%i
	)
	for /f "tokens=3" %%i in ('2^>nul dir /-c /a-d *.jpg *.png *.bmp *.mp4 *.avi *.mov *.mkv ^|findstr /iec:" 字节"') do (
		for /f "delims=." %%a in ('powershell -c "%%i/1024/1024"') do (
			set z=%%a
		)
	)
	popd
	call ren "%%d" "%%d %%p%%p %%v%%v %%z%%m"
)
pause
复制代码

@echo off &set "zF=%cd%\z.tmp" &setlocal enabledelayedexpansion
for /d %%a in (*) do (
    set/a "p=v=z=0"
    pushd "%%a"
    ( for %%b in (*.jpg *.png *.bmp) do (
          echo,%%~zb
          if not "%%~nb"=="000" if not "%%~nb"=="00.1" if not "%%~nb"=="00.2" if not "%%~nb"=="00.3" set/a p+=1)
      for %%c in (*.mp4 *.avi *.mov *.mkv) do (set/a "v+=1"&echo,%%~zc)
    )>"%zF%"
    for /f %%z in (' powershell "$z=0;gc '%zF%'|foreach{$z+=$_};[math]::round($z/1mb)" ') do set "z=%%z"
    REM for /f %%z in (' gawk "{z+=$1;print int(z/1024/1024)}" "%zF%" ') do set "z=%%z"
    popd
    ren "%%a" "%%a [!p!P!v!V-!z!M]"
)
del/q "%zF%"&endlocal&pause&exit/b
复制代码

@echo off &setlocal enabledelayedexpansion
set "pF=*.jpg *.png *.bmp"
set "vF=*.mp4 *.avi *.mov *.mkv"
set "s=" &for %%x in (.jpg .png .bmp) do for %%f in (000 00.1 00.2 00.3) do (set "s=!s! %%f%%x")
for /d %%d in (*) do (
    set/a "n=p=v=z=0" &pushd "%%d"
    for /f %%n in (' dir /b/a-d !s!^|find /c /v "" ') do set "n=%%n"
    for /f %%p in (' dir /b/a-d !pF!^|find /c /v "" ') do set/a "p=%%p-n"
    for /f "tokens=1-3 delims= " %%a in (
    	' dir /-c !pF! !vF!^| find /i "个文件" ') do (set/a "v=%%a-p-n"&set "z=%%c")
    for /f %%z in (' powershell -c "[math]::round(!z!/1mb)" ') do set "z=%%z"
    REM for /f %%z in (' gawk "BEGIN{print(int(!z!/1024/1024))}" ') do set "z=%%z"
    popd &ren "%%d" "%%d [!p!P!v!V-!z!M]"
)
endlocal&pause&exit/b
复制代码