[文本处理] 想VBA和PDFtk结合给指定的PDF加标签，中途报错，求方案。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for %%i in ("%f%") do set _nf=%%~ni&set _xf=%%~xi
set /a n=1
rem skip数值以 "以下为书签名单" 所在行为准
(for /f "skip=24 tokens=* delims=" %%a in ('type "%~f0"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>bookmark.txt
pdftk "%f%" update_info_utf8 bookmark.txt output "%_nf%_bookmark%_xf%"
del /q bookmark.txt
pause&exit

以下为书签名单：
红旗小学1
红旗小学2
红旗小学3
红旗小学4
红旗小学5
红旗小学6
红旗小学7
红旗小学8
红旗小学9
红旗小学10
红旗小学11
红旗小学12
红旗小学13
红旗小学14
红旗小学15
红旗小学16
红旗小学17
红旗小学18
红旗小学19
红旗小学20
红旗小学21
红旗小学22
红旗小学23
红旗小学24
红旗小学25
红旗小学26
红旗小学27
红旗小学28
红旗小学29
红旗小学30
复制代码

(for /f "delims=" %%a in ('type "标签.txt"') do (
复制代码

<# ::
@echo off &if not exist "*.pdf" (exit/b) else if not exist "标签.txt" exit/b
powershell "iex(${%~f0}|out-string)" &if not exist "BMu8.txt" exit/b
for %%F in (*.pdf) do (set "pF=%%F"&set "_pF=%%~nF.new.pdf")
pdftk.exe "%pF%" update_info_utf8 "BMu8.txt" output "%_pF%"
del "BMu8.txt"&pause&exit/b
#>
$n=1; $s=foreach($l in gc "标签.txt") {
	echo("BookmarkBegin`nBookmarkTitle: "+$l+"`nBookmarkLevel: 1`nBookmarkPageNumber: "+($n++))
}; [io.file]::writeAlllines("BMu8.txt", $s); exit
复制代码

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for /f "delims=" %%i in ("%f%") do set _nf=%%~dpni&set _xf=%%~xi&set _pf=%%~dpi
set /a n=1
rem 标签.txt一定一定要保存为UTF-8编码格式的txt文件
(for /f "delims=" %%a in ('type "!_pf!标签.txt"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>!_pf!bookmark.txt
%~dp0pdftk "!f!" update_info_utf8 "!_pf!bookmark.txt" output "!_nf!_bookmark!_xf!"
del /q !_pf!bookmark.txt
echo.&echo.书签添加完毕！&timeout /t 3 &exit
复制代码

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for /f "delims=" %%i in ("%f%") do set _nf=%%~ni&set _xf=%%~xi&set _pf=%%~dpi
set /a n=1
(for /f "delims=" %%a in ('type "!_pf!标签.txt"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>bookmark.txt
"%~dp0pdftk" !f! update_info_utf8 "!_pf!bookmark.txt" output "!_pf!!_nf!_bookmark!_xf!"
rem 备份源文件，需要去掉前面两个 :: 冒号
::ren "!f!" "!_nf!_bak!_xf!"
move /y "!_nf!_bookmark!_xf!" !f! >nul
del /q "!_pf!bookmark.txt"
echo.&echo.书签添加完毕！&timeout /t 3&exit
复制代码

@echo off
rem "批处理调用pdftk给无书签的pdf文件按照 书签文本每一行对应pdf每一页 添加书签（如果某页不需要书签，则书签文本对应行留空）"
rem "批处理和书签文本全部保存为utf-8编码，pdftk添加到环境变量，书签文本格式txt，与pdf文件同名"
chcp 65001 >nul
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
	if exist "%%~ni.txt" (
		pdftk "%%i" dump_data_utf8 output |find "BookmarkTitle:" 1>nul
		if errorlevel 1 (
			(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%~ni.txt"') do (
				if "%%b" neq "" (
					echo BookmarkBegin
					echo BookmarkTitle: %%b
					echo BookmarkLevel: 1
					echo BookmarkPageNumber: %%a
				)
			))>report.txt
			pdftk "%%i" update_info_utf8 report.txt output "%%~ni_new.pdf"
		)
	) else (
		echo 未找到文本 [%%~ni.txt]
	)
)
del report.txt 2>nul
pause
复制代码