批处理怎样在文件夹后追加文件夹内视频总时长？ - BAT求助&讨论 - 批处理之家 BAT,CMD,批处理,PowerShell,VBS,DOS

Rank: 3 Rank: 3

帖子: 171
积分: 230
技术: 0
捐助: 0
注册时间: 2022-7-9

16楼 跳转到 »

发表于 2024-1-28 20:25 | 只看该作者

回复 13# newswan

提示如下图，帮我再看看，我上传例子文件到百度云盘了，谢谢。

链接：https://pan.baidu.com/s/1mPzdlyhFy4UY1l6OECw7IA?pwd=nro4
提取码：nro4
--来自百度网盘超级会员V10的分享

ppll2030

四级士官

Rank: 3 Rank: 3

帖子: 181
积分: 255
技术: 21
捐助: 0
注册时间: 2023-9-27

17楼

发表于 2024-1-28 20:34 | 只看该作者

本帖最后由 ppll2030 于 2024-1-28 22:26 编辑

回复 15# qd2024

毒盘非会员，无法下载。

复制代码保存为bat文件，然后视频文件夹拖拽到bat文件上就可以了。
脚本需要第三方ffmpeg.exe。
第三行的ffmpeg路径请修改为自己的实际路径。
提示找不到文件，可能视频后缀名不对。已添加多个常用视频
照搬二楼的码。去除echo，无法更名的bug，12楼的已更正

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

18楼

发表于 2024-1-28 20:44 | 只看该作者

回复 16# qd2024

不好意思，没有实际运行，忘记了 ren 不能用全路径
用了两种方法

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

set ffPath=D:\Program Files

set folderPath=%~dp1
set folderName=%~nx1

pushd "%folderPath%\%folderName%"

set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mkv `) do (
	for /f "usebackq tokens=1,2 delims=." %%i in (`" "%ffpath%\ffprobe.exe" -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 "%%a" "`) do (
		set/a time+=%%i
	)
)
set/a time/=60
echo %time%

set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mkv `) do (
	for /f "usebackq tokens=2,3,4 delims=:. " %%i in (` ""%ffpath%\ffprobe.exe" "%%a" 2>&1 | findstr Duration" `) do (
		set /a time+=%%i*3600+%%j*60+%%k
	)
)
set/a time/=60
echo %time%

popd

pushd "%folderPath%"
echo ren "%folderName%" "%folderName%[%time%]"
popd

pause
exit/b
复制代码

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

19楼

发表于 2024-1-28 20:46 | 只看该作者

没下载你的文件，太大，用自己的文件测试了可行

buyiyang

中尉

Rank: 5 Rank: 5

帖子: 427
积分: 803
技术: 119
捐助: 0
注册时间: 2022-3-26

20楼

发表于 2024-1-28 20:46 | 只看该作者

@if(0)==(0) @echo off
cd /d "%~dp0"
for /d %%d in (*) do (
    pushd "%%d"
    for /f "delims=" %%i in ('dir /b /a-d "*.mp4"^|cscript /e:jscript /Nologo "%~f0"') do (
    popd
    ren "%%d" "%%d【%%i】"
    )
)
pause&exit
@end
objPlayer=new ActiveXObject("WMPlayer.OCX"),ws=WSH.stdin,durationInSeconds=0;
while (!ws.atendofstream) {
    var filePath = ws.readline();
    var objMedia = objPlayer.newMedia(filePath);
    durationInSeconds += objMedia.duration
}
WScript.Echo(Math.ceil(durationInSeconds/60));
复制代码

Rank: 3 Rank: 3

帖子: 171
积分: 230
技术: 0
捐助: 0
注册时间: 2022-7-9

21楼

发表于 2024-1-28 21:59 | 只看该作者

回复 18# newswan
我把代码调成这样

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set ffPath=D:\Program Files
 
set folderPath=%~dp1
set folderName=%~nx1
 
pushd "%folderPath%\%folderName%"
 

set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq tokens=2,3,4 delims=:. " %%i in (` ""%ffpath%\ffprobe.exe" "%%a" 2>&1 | findstr Duration" `) do (
		set /a time+=%%i*3600+%%j*60+%%k
	)
)
set/a time/=60
echo %time%
 
popd
 
pushd "%folderPath%"
ren "%folderName%" "%folderName%【%time%】"
popd
 
pause
exit/b
复制代码

把文件夹拖到BAT上，提示如下图，再帮我看盾是什么原因，别一段提示找不文件

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

22楼

发表于 2024-1-28 23:59 | 只看该作者

回复 15# qd2024

以0开头的数字

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
chcp 936

set ffPath=D:\Program Files

set folderPath=%~dp1
set folderName=%~nx1


pushd "%folderPath%\%folderName%"

echo "--1--"
set time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq" %%i in (`" "%ffpath%\ffprobe.exe" -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 "%%a" "`) do (
		set time=!time! + %%i
	)
)
for /f "usebackq" %%a in (` powershell -command " [math]::Ceiling( (%time%) / 60 ) " `) do (
	set time=%%a
)
echo %time%

echo "--2--"
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq tokens=1,2 delims=." %%i in (`" "%ffpath%\ffprobe.exe" -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 "%%a" "`) do (
		set/a time+=%%i
	)
)
set/a time/=60
set/a q=%time%%60
if %q% gtr 0 (set/a time+=1)
echo %time%

echo "--3--"
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq tokens=2,3,4 delims=:. " %%i in (` ""%ffpath%\ffprobe.exe" "%%a" 2>&1 | findstr Duration" `) do (
		set/a time+=1%%i*3600+1%%j*60+1%%k-100*3600-100*60-100
	)
)
set/a time/=60
set/a q=%time%%60
if %q% gtr 0 (set/a time+=1)
echo %time%

popd

pushd "%folderPath%"
echo ren "%folderName%" "%folderName%[%time%]"
popd

pause
exit/b
复制代码

Rank: 3 Rank: 3

帖子: 171
积分: 230
技术: 0
捐助: 0
注册时间: 2022-7-9

23楼

发表于 2024-1-29 12:09 | 只看该作者

回复 22# newswan

成功谢谢有没有可能实际对二级目录的批量处理就是拖一个文件夹，这个文件夹根下没有视频文件，这个文件夹下有多个文件夹内包含视频文件，对这些文件夹进行追加时长处理

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

24楼

发表于 2024-1-29 12:32 | 只看该作者

回复 23# qd2024

这个涉及到一个问题，仅本文件夹？包含子文件夹

Rank: 3 Rank: 3

帖子: 171
积分: 230
技术: 0
捐助: 0
注册时间: 2022-7-9

25楼

发表于 2024-1-29 14:20 | 只看该作者

回复 24# newswan

这样被拖到BAT上的文件夹A里不包含视频文件  A下有B C D等文件夹 B C D等文件夹内有视频文件  ，
            A拖到BAT上后，统计BCD文件时长，统计后变为B【XX】  C【XX】  D【XX】
            如果A能追加上其下所有子目录的时长更好。
   不知道有没有表达明白，谢谢。

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

26楼

发表于 2024-1-29 17:36 | 只看该作者

明白，还有个问题，上面是每个文件夹时长总和去整。不是每个视频时长去整再想加

aloha20200628

Rank: 5 Rank: 5

帖子: 874
积分: 1456
技术: 189
捐助: 0
注册时间: 2021-10-13

27楼

发表于 2024-1-29 17:38 | 只看该作者

本帖最后由 aloha20200628 于 2024-1-29 20:10 编辑

回复 25# qd2024

看楼主用数学题轮训各位热心解答者，也跟一帖。
代码说明：
一。获取dir简报结果至少须用 "delims=" 禁止系统分隔符（,; =），须用 /s 获取全路径文件名
二。用双引号包裹命令表达式，减少打理转义符的麻烦
三。ffprobe筛选时长的参数表达式虽然很多，但其输出效率之差可忽略，选择最轻量化代码即可
四。本帖要求时长误差是分钟级，故可免去调用外部浮点运算功能

以下代码可存为test.bat，将一级目录拖给它即可，完成一级目录及其子目录的更名》源目录名【时长】。

@echo off
if "%~1"=="" (exit/b) else (setlocal enabledelayedexpansion)
set fpb="C:\ffmpeg\bin\ffprobe.exe"
for /f "delims=" %%D in (' dir /b/s/ad "%~1" ') do (
	for /f "delims=" %%F in (' dir /b/s/a-d "%%~D\*.mp4" ') do (
		for /f "tokens=1-4 delims=:. " %%1 in (' "%fpb% "%%~F" 2>&1 | findstr /ic:"Duration:" " ') do (
			set/a "m+=%%2*60+%%3,s+=%%4">nul 2>nul
		)
	)
	set/a "ms=s/60,sm=s%%60,m+=ms">nul 2>nul
	if !sm! neq 0 (set/a m+=1)
	ren "%%~D" "%%~nxD【!m!】" & set/a "mm+=m,m=s=0"
)
ren "%~1" "%~nx1【!mm!】"
endlocal&exit/b
复制代码

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

28楼

发表于 2024-1-29 18:01 | 只看该作者

回复 27# aloha20200628

各人习惯，不调用 find 比较好
或者用 vbs 计算也好，powershell 慢，但是我对 vbs 不太明白。

aloha20200628

Rank: 5 Rank: 5

帖子: 874
积分: 1456
技术: 189
捐助: 0
注册时间: 2021-10-13

29楼

发表于 2024-1-29 19:56 | 只看该作者

给一个不调用ffprobe.exe的bat+jscript混编版本，直接调用windows系统内置的fso功能获取媒体文件属性（如时长），与用ffprobe.exe/mediainfo.exe等外部方法对比可明显提速（尤其是大目录操作），因批处理脚本调用后者是逐个文件处理，而前者能一次性批量处理。
以下代码可存为test.bat，将一级目录拖给它即可，完成一级目录及其子目录的更名》源目录名【时长】。

@set @v=1 /*
@echo off
if "%~1"=="" (exit/b) else (setlocal enabledelayedexpansion)
(for /f "delims=" %%D in (' dir /b/s/ad "%~1" ') do (
	for /f %%v in (' " dir/b/s/a-d "%%~D\*.mp4"|cscript /e:jscript "%~f0" " ') do (set "m=%%v")
	set/a "mm+=!m!" & ren "%%~D" "%%~nxD【!m!】"
)
ren "%~1" "%~nx1【!mm!】" & endlocal & exit/b) 2>nul
*/
m = s = ms = sm = 0, ws = WSH.stdin, sa = WSH.createobject('shell.application');
while (!ws.atendofstream) {
	F = ws.readline(); i = F.lastIndexOf('\\'), pF = F.substr(0,i+1), nF = F.substr(i+1);
	ns = sa.namespace(pF), pn = ns.parsename(nF); d = ns.getdetailsof(pn,27).split(':');
	m += ~~d[0]*60 + ~~d[1]; s += ~~d[2];
}
WSH.echo(m+=Math.ceil(s/60));
复制代码

Rank: 3 Rank: 3

帖子: 171
积分: 230
技术: 0
捐助: 0
注册时间: 2022-7-9

30楼

发表于 2024-1-29 20:02 | 只看该作者

回复 26# newswan

这样被拖到BAT上的文件夹A里不包含视频文件  A下有B C D等文件夹 B C D等文件夹内有视频文件  ，
            A拖到BAT上后，统计BCD文件时长，统计后变为B【XX】  C【XX】  D【XX】
            如果A能追加上其下所有子目录的时长更好。
   不知道有没有表达明白，谢谢。

  就是说  B C D……只计算自己文件夹下的视频的时间和，A是把所有子目录的所有视频时间和标记出来