批处理之家 » BAT求助&讨论 » [已解决]批处理如何遍历多层目录下的文件夹名称并修改？

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 2

帖子: 80
积分: 162
技术: 0
捐助: 0
注册时间: 2023-1-27

1楼 跳转到 » 倒序看帖

字体大小: tT

发表于 2024-1-19 23:22 | 只看该作者

[文件操作] [已解决]批处理如何遍历多层目录下的文件夹名称并修改？

本帖最后由 liaoguinan 于 2024-1-21 19:05 编辑

如图如何遍历多层文件夹下发现我爱小明文件夹后把我爱小明文件夹去掉“我爱”两字

1 评分人数

Batcher: 感谢给帖子标题标注[已解决]字样PB + 2

Rank: 3 Rank: 3

帖子: 181
积分: 255
技术: 21
捐助: 0
注册时间: 2023-9-27

2楼

发表于 2024-1-20 00:27 | 只看该作者

把bat文件放在一级目录下运行。
预览无误后，把第4行的“echo”删除，再次运行即可更名。

@echo off &setlocal enabledelayedexpansion
for /f  "delims=" %%i in ('dir /b /s /ad ^| find "我爱"') do (
	set oldname=%%~ni&set newname=!oldname:我爱=!
	echo ren %%i !newname!
)
pause
复制代码

Rank: 8 Rank: 8

帖子: 567
积分: 1151
技术: 91
捐助: 298
注册时间: 2017-3-17

3楼

发表于 2024-1-20 13:13 | 只看该作者

回复 2# ppll2030

想一下，二级目录被改名之后，轮到三级目录改名的时候它还以为二级目录是旧名字呢，会出错吧。

测试代码之前请做好备份

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

4楼

发表于 2024-1-20 14:13 | 只看该作者

回复 3# ShowCode

递归，先处理子目录
powershell

function xren() {
	param( [String]$dir )
	Push-Location $dir
	Get-ChildItem -Directory | ForEach-Object {
		xren $_.Name
		echo $_.FullName
		Rename-Item $_.FullName -newname ("x" + $_.Name)
	}
	Pop-Location
}

xren .
复制代码

Rank: 5 Rank: 5

帖子: 1066
积分: 1453
技术: 103
捐助: 0
注册时间: 2010-6-20

5楼

发表于 2024-1-20 14:34 | 只看该作者

批处理

@echo off
setlocal enabledelayedexpansion

call :C_ren .

pause
exit/b

:C_ren
	pushd %1
	for /f  "usebackq delims=" %%i in (` dir /b /ad `) do (
		call :C_ren %%i
		echo %%~fi
		set oldname=%%~ni
		set newname=x%%~ni
		echo ren %%i !newname!
	)
	popd
goto :eof
复制代码

1 评分人数

ppll2030: 逻辑能力真强~！技术 + 1

Rank: 3 Rank: 3

帖子: 181
积分: 255
技术: 21
捐助: 0
注册时间: 2023-9-27

6楼

发表于 2024-1-20 20:27 | 只看该作者

回复 3# ShowCode

哈哈。好像是有这个问题。那就再加个反向列出应该就可以了。

@echo off &setlocal enabledelayedexpansion
for /f  "delims=" %%i in ('dir /b /s /ad ^| find "我爱" ^| sort /r') do (
	set oldname=%%~ni&set newname=!oldname:我爱=!
	echo ren %%i !newname!
)
pause
复制代码

Rank: 2

帖子: 80
积分: 162
技术: 0
捐助: 0
注册时间: 2023-1-27

7楼

发表于 2024-1-20 22:15 | 只看该作者

回复 6# ppll2030

运行空白没见有反应？去掉echo显示语法错误

Rank: 5 Rank: 5

帖子: 879
积分: 1464
技术: 190
捐助: 0
注册时间: 2021-10-13

8楼

发表于 2024-1-21 11:22 | 只看该作者

本帖最后由 aloha20200628 于 2024-1-21 15:05 编辑

请 for /d /r ... 简化一下
如下脚本置于一级目录下运行
针对本例版

@echo off & for /d /r %%d in (*我爱小明*) do ren "%%~d" "小明"
复制代码

兼容性版

@echo off & setlocal enabledelayedexpansion
for /d /r %%d in (*我爱小明*) do (set "n=%%d" & ren "%%~d" "!n:我爱小明=小明!")
复制代码

Rank: 3 Rank: 3

帖子: 181
积分: 255
技术: 21
捐助: 0
注册时间: 2023-9-27

9楼

发表于 2024-1-21 12:17 | 只看该作者

回复 7# liaoguinan

不应该啊？！
我这边测试没问题啊。
二楼的可以运行不？如果可以，那可能是你系统缺少sort.exe文件了。
我只是在二楼的基础上添加了sort的反向排序而已。

Rank: 6 Rank: 6

帖子: 1702
积分: 2790
技术: 342
捐助: 50
注册时间: 2022-9-18

10楼

发表于 2024-1-21 17:20 | 只看该作者

如果仅仅是去掉文件夹名为 “我爱小明” 中的“我爱”

@echo off
rem 批处理保存为ansi编码格式
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /ad "我爱小明" ^|sort /r') do (
	ren "%%i" "小明"
)
pause
复制代码

1 评分人数

liaoguinan: 感谢技术 + 1

bat小白，请多指教！谢谢！

Rank: 2

帖子: 80
积分: 162
技术: 0
捐助: 0
注册时间: 2023-1-27

11楼

发表于 2024-1-21 17:35 | 只看该作者

回复 10# 77七

完美