[文本处理] 批处理随机复制txt到多个子目录？

<# :
@echo off
powershell -NoProfile -ExecutionPolicy bypass "Get-Content -literal '%~f0' |Out-String|Invoke-Expression"
pause
#>
$txt=dir D:\TXT文件夹\*.txt -File
dir E:\123文件夹\ -Directory|%{$randtxt=$txt|Get-Random -Count 1;copy $randtxt $_.FullName}
复制代码

@echo off&pause

set "f=D:\TXT文件夹"
set "fd=E\123文件夹"

for /r "%f%" %%a in ("*.txt") do set /a n+=1

for /d %%a in ("%fd%\*") do (
set folder=%%a
call :aaa
)

echo,&pause&exit /b

:aaa
set /a r=%random% %% %n%+1
set m=0
for /r "%f%" %%b in ("*.txt") do (
set file=%%b
set /a m+=1
setlocal enabledelayedexpansion
if !m! == !r! (
rem echo,!r!
echo,&echo copy "!file!" to "!folder!"
copy /y "!file!" "!folder!"
endlocal
goto :eof
)
endlocal
)
复制代码

@echo off&setlocal enabledelayedexpansion
set "f=D:\txt文件夹"
set "fd=E:\123文件夹\"
for /f "delims=" %%f in ('dir /b /a-d "%f%\*.txt"') do set /a n+=1&set "_!n!=%%~f"
for /f "delims=" %%d in ('dir /b /ad "%fd%"') do (
     set /a r=!random!%%n+1
     for %%b in (!r!) do copy "%f%\!_%%b!" "%fd%%%d\"
)
pause
复制代码

@echo off
set "f1=D:\TXT"
set "f2=E:\123"
for %%a in ("%f1%\*.txt") do (
	set /a n+=1
	call set _%%random%%_%%n%%=%%a
)
for /d %%d in ("%f2%\*") do (
	call :1 "%%d"
)
pause & exit

	:1
	for /f "tokens=1* delims==" %%a in ('2^>nul set _') do (
		copy "%%b" "%~1"
		set %%a=
		exit /b
	)
	exit /b
复制代码