dir *.txt | Rename-Item -NewName {($_.BaseName -replace '[ .]','')+$_.Extension}COPY

@echo off
chcp 65001 >nul
rem 批处理保存为utf-8编码格式，需要ffmpeg ffprobe，自行修改相关路径
for /f "delims=" %%i in ('dir /b /s /a-d *.mp3') do (
	for /f "tokens=1-2 delims==" %%a in ('ffprobe -loglevel 0 -show_streams "%%i" ^|findstr /bc:"bit_rate="') do (
		if not "%%b" equ "128000" (
			ffmpeg -i "%%i" -ab 128k "xxx.mp3"
			move /y "xxx.mp3" "%%i"
		)
	)
)
pauseCOPY

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d *.mp3') do (
    set "OldName=%%~ni"
    set "NewName=!OldName:~0,4!%%~xi"
    ren "%%i" "!NewName!"
)COPY

@echo off
chcp 65001 >nul
rem 批处理保存为utf-8编码格式，需要ffmpeg ffprobe，自行修改相关路径
for /f "delims=" %%i in ('dir /b /s /a-d *.mp3') do (
        setlocal enabledelayedexpansion
        ffprobe -loglevel 0 -show_streams "%%i" |findstr /xc:"bit_rate=128000" 1>nul || set str1=-ab 128k
        ffprobe -loglevel 0 -show_streams "%%i" |findstr /xc:"sample_rate=44100" 1>nul || set str2=-ar 44100
        if not defined str1 if not defined str2 (
                ver >nul
        ) else (
                ffmpeg -i "%%i" !str1! !str2! "xxx.mp3"
                move /y "xxx.mp3" "%%i"
        )
        endlocal
)
pauseCOPY

@echo off
chcp 65001 >nul
rem 批处理保存为utf-8编码格式，需要ffmpeg ffprobe，自行修改相关路径
for /f "delims=" %%i in ('dir /b /s /a-d *.mp3') do (
	setlocal enabledelayedexpansion
	ffprobe -loglevel 0 -show_streams "%%i" |findstr /xc:"bit_rate=128000" 1>nul || set str1=-ab 128k
	ffprobe -loglevel 0 -show_streams "%%i" |findstr /xc:"sample_rate=44100" 1>nul || set str2=-ar 44100
	if "!str1!!str2!" neq "" (
		ffmpeg -i "%%i" !str1! !str2! "xxx.mp3"
		move /y "xxx.mp3" "%%i"
	)
	endlocal
)
pauseCOPY

@echo off
rem 批处理保存为ansi编码格式
rem 使用前先备份
rem 第1次执行为备份文件名，第2次执行为恢复文件名。
rem 批处理在各目录下生成一个 listx.txt 保存原始文件名。各目录下mp3文件 “序号”不变、数量不变 前提下使用。
dir /b /s /a-d listx.txt 1>nul 2>&1 && goto :re
for /d %%d in (*) do (
	pushd "%%d"
	(for /f "delims=" %%i in ('dir /b /a-d *.mp3 ^|sort') do (
		echo %%i
	))>listx.txt
	popd
)
pause
exit
 
:re
rem http://bbs.bathome.net/viewthread.php?tid=66400
setlocal enabledelayedexpansion
for /d %%d in (*) do (
	pushd "%%d"
	(for /f "delims=" %%i in ('dir /b /a-d *.mp3 ^|sort') do (
		set /p str=
		ren "%%i" "!str!"
	))<"listx.txt"
	del "listx.txt"
	popd
)
pauseCOPY