[文件操作] 比较复杂的逻辑查询功能历史数据几万bat能胜任吗

@echo off & cd /d "%~dp0"
setlocal enabledelayedexpansion
REM 读取目标
set "index=0"
for /d %%i in ("需要查询的目标\*") do (
	set /a "index+=1"
	set "_tag_!index!=%%~nxi"
)
REM 查询历史
for /d %%i in ("顶层文件夹o被查询的历史目录\*") do (
	echo %%i
	set /a "a=0,b=0"
	for /d %%a in ("%%i\*") do set /a "a+=1"
	for /l %%a in (1,1,%index%) do if exist "%%i\!_tag_%%a!" set /a "b+=1"
	if "!b!"=="!index!" (
		if "!a!"=="!index!" (
			echo 完全匹配
			copy /y "%%i\*.xlsx" "结论输出" | findstr "已复制"
		) else (
			echo 包含案例
			copy /y "%%i\*.xlsx" "结论包含" | findstr "已复制"
		)
	) else echo 不匹配
	echo -----------------
)
pause&exit
复制代码

@echo off & cd /d "%~dp0"
setlocal enabledelayedexpansion
REM 读取目标
set "index=0"
for /f "delims=_" %%i in ('dir /b /ad "需要查询的目标\*"') do (
	set /a "index+=1"
	set "_tag_!index!=%%~i"
)
REM 查询历史
for /d %%i in ("顶层文件夹o被查询的历史目录\*") do (
	echo %%i
	set /a "a=0,b=0"
	for /d %%a in ("%%i\*") do set /a "a+=1"
	for /l %%a in (1,1,%index%) do dir /b /ad "%%i" | findstr /b /i /c:"!_tag_%%a!" >nul 2>nul && set /a "b+=1"
	if "!b!"=="!index!" (
		if "!a!"=="!index!" (
			echo 完全匹配
			copy /y "%%i\*.xlsx" "结论输出" | findstr "已复制"
		) else (
			echo 包含案例
			copy /y "%%i\*.xlsx" "结论包含" | findstr "已复制"
		)
	) else echo 不匹配
	echo -----------------
)
pause&exit
复制代码