[其他] [已解决]BAT脚本达到微信多开的问题

Rank: 1

帖子: 16
积分: 29
技术: 0
捐助: 0
注册时间: 2018-3-26

1楼 跳转到 » 倒序看帖

打印

字体大小: tT

发表于 2018-11-2 11:38 | 只看该作者

[其他] [已解决]BAT脚本达到微信多开的问题

请问大佬们，想弄个微信多开，目前是这种用的其他大佬的（我本人是小白一枚0.0）：

@echo off

cd /d "%SrcDir%"
color 0f

:start
echo 请输入要打开微信的个数：
set /p answer=

for /l %%i in (1,1,%answer%) do start WeChat.exe
复制代码

但是这种不适合所有人使用，因为每个人微信安装位置不一样，这个必须要放在微信安装目录下才能正确运行。请问要怎么写，才能够不管微信安装在哪儿，bat不管放哪儿都可以直接多开呢？请大佬指教。

Rank: 5 Rank: 5

帖子: 635
积分: 969
技术: 107
捐助: 0
注册时间: 2017-11-23

2楼

发表于 2018-11-2 13:04 | 只看该作者

办法当然有,第一次运行的话肯定要全盘扫描的,扫描到WeChat.exe可以将路径记录到流文件.以后运行就不需要再扫描了.
不过将微信的路径设置到BAT里更快不是吗?

QQ 33892006

Rank: 1

帖子: 16
积分: 29
技术: 0
捐助: 0
注册时间: 2018-3-26

3楼

发表于 2018-11-2 13:22 | 只看该作者

回复 2# yhcfsr

快是快，但是每个人安装电脑路径不一样啊，别人找我要这个我直接就发给别人了，很多同事压根儿都不知道什么路径啥的。。。

Rank: 1

帖子: 16
积分: 29
技术: 0
捐助: 0
注册时间: 2018-3-26

4楼

发表于 2018-11-2 13:23 | 只看该作者

回复 2# yhcfsr

请问你说的那个怎么写代码呢？

Batcher

管理员

Rank: 12

帖子: 14935
积分: 46142
技术: 857
捐助: 745
注册时间: 2008-6-9

5楼

发表于 2018-11-2 13:39 | 只看该作者

参考：
http://bbs.bathome.net/thread-3465-1-1.html

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 5 Rank: 5

帖子: 635
积分: 969
技术: 107
捐助: 0
注册时间: 2017-11-23

6楼

发表于 2018-11-2 15:27 | 只看该作者

回复 5# Batcher

参考老大提供的帖子,写了个,题主做下参考.

@echo off
rem 此脚本实现微信多开功能

set "FileName=wechat.exe"
set "script_path=%~f0"
(set/p wechat=<"%script_path%:WX") 2>nul
if "%wechat%" equ "" (echo 首次运行,正在扫描微信...) else goto :start_wechat

(for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        pushd %%a:\
        for /r %%b in (*%FileName%) do (
            if /i "%%~nxb" equ "%FileName%" (
				
                echo,%%b|findstr /v "%tmp%"&&(
					echo %%b>"%script_path%:WX"
					goto :start_wechat
				)
            )
        )
        popd
    )
))>nul 2>nul
echo;对不起,没有找到微信
pause&exit

:start_wechat
set/p wechat=<"%script_path%:WX"
set /p "num=亲要开几个微信:"
for /l %%a in (1,1,%num%) do start "" "%wechat%"
复制代码

QQ 33892006

hnfeng

五级士官

Rank: 4

帖子: 244
积分: 305
技术: 7
捐助: 0
注册时间: 2012-4-21

7楼

发表于 2018-11-2 15:43 | 只看该作者

扫硬盘？运行一下就扫一遍？扫到什么时候啊

直接读注册表里面微信的位置

whiter

Rank: 1

帖子: 15
积分: 27
技术: 0
捐助: 0
注册时间: 2016-1-8

8楼

发表于 2018-11-2 16:18 | 只看该作者

直接修改电脑的环境变量啊,电脑属性--高级--环境变量设置
或者 reg add命令添加注册表位置应该是:[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment]
应该可以,具体实现我没试

Rank: 5 Rank: 5

帖子: 635
积分: 969
技术: 107
捐助: 0
注册时间: 2017-11-23

9楼

发表于 2018-11-2 16:33 | 只看该作者

本帖最后由 yhcfsr 于 2018-11-2 17:06 编辑

回复 7# hnfeng

亲测,装在C盘扫描2秒.E盘约6秒.
只会在首次运行时扫描一次.

读注册表的方法很好,我试试完善下.非常感谢指点^V^ .

@echo off
rem 此脚本实现微信多开功能.

for /f "tokens=2*" %%a in ('reg query "HKEY_CURRENT_USER\Software\Tencent\WeChat" /v InstallPath 2^>nul') do set "wechat=%%b"
if not defined wechat echo;没有找到微信&pause&exit
set /p "num=亲要开几个微信:"
for /l %%a in (1,1,%num%) do start "" "%wechat%\WeChat.exe"
复制代码

QQ 33892006

Rank: 1

帖子: 16
积分: 29
技术: 0
捐助: 0
注册时间: 2018-3-26

10楼

发表于 2018-11-2 16:56 | 只看该作者

回复 6# yhcfsr

大佬，这个出现丢失ssleay32.dll和wechatwin.dll文件缺失怎么解决呢？直接打开微信有没有出现这个

hnfeng

五级士官

Rank: 4

帖子: 244
积分: 305
技术: 7
捐助: 0
注册时间: 2012-4-21

11楼

发表于 2018-11-2 17:04 | 只看该作者

C:\Windows\System32>for /f "tokens=1,2*" %a in ('reg query HKCU\Software\Tencent\WeChat /v InstallPath ^| find /i "REG_SZ" ') do set WeChatPath=%c

C:\Windows\System32>set WeChatPath=C:\Program Files (x86)\Tencent\WeChat
复制代码

Rank: 5 Rank: 5

帖子: 635
积分: 969
技术: 107
捐助: 0
注册时间: 2017-11-23

12楼

发表于 2018-11-2 17:12 | 只看该作者

回复 10# love303929545

先试试9楼的代码吧.
至于6楼代码出问题,需要看调试信息.可能是获取路径出了问题.
我测试时也发现临时目录也会出现WECHAT.exe,所以我排除了临时目录(可能系统不一样,临时目录的环境变量不太一样,我应该用Temp不应该用tmp)

QQ 33892006

Batcher

管理员

Rank: 12

帖子: 14935
积分: 46142
技术: 857
捐助: 745
注册时间: 2008-6-9

13楼

发表于 2018-11-2 17:21 | 只看该作者

参考：自动获取QQ路径的几种方法：读注册表、全盘搜索、获取进程信息等
http://bbs.bathome.net/thread-4193-1-1.html

Rank: 1

帖子: 16
积分: 29
技术: 0
捐助: 0
注册时间: 2018-3-26

14楼

发表于 2018-11-4 13:40 | 只看该作者

回复 12# yhcfsr

多谢大佬。9楼完美解决了。

刚刚刚刚好

Rank: 1

帖子: 2
积分: 13
技术: 0
捐助: 0
注册时间: 2019-2-1

15楼

发表于 2019-2-3 17:42 | 只看该作者

start D:\微信\WeChat\WeChat.exe
start D:\微信\WeChat\WeChat.exe
对于能查看路径的直接改后面路径
再说了右键微信的快捷方式属性就能看到微信路径直接复制多省事