[文本处理] 批处理如何判断输入的字符串是否是指定位数的纯数字

'&start Wscript -e:vbscript "%~0"
a=inputbox("")
if len(a) = 48 and IsNumeric(a) then
wscript.echo "True"
else
wscript.echo "False"
end if
复制代码

'&start Wscript -e:vbscript "%~0"
Set a=New RegExp
a.Pattern="\b\d{48}\b"
MsgBox a.Test(InputBox(""))
复制代码

Echo off&cls&setlocal   ENABLEDELAYEDEXPANSION
for /l %%a in (1,1,48) do set pattern=!pattern![0-9]
Set/pa=
echo !a!|Findstr "^%pattern%$" >nul && Echo True || Echo False
Pause
复制代码

@echo off&setlocal enabledelayedexpansion
set /p "a=请输入48位数字: 注:如果闪退则是包含特殊字符或是超限字符:
if defined a (
 set "#=!a!"
 (for /l %%n in (0,1,9)do set "#=%%n!#!"&&set "#=!#:%%n=!")>nul 2>nul
 if defined # (
  echo,非纯数字
 )else (
  set "n=0"
  for /l %%n in (0,1,8197)do if /i not "!a:~%%n,1!"=="" set/a "n=%%n+1"
  if /i "!n!"=="48" (
   echo,纯数字验证正确
  )else (
   echo,验证错误字符数:!n!
  )
 )
)else (
 echo,直接回车了
)
复制代码

@echo off
setlocal enabledelayedexpansion

:INPUT
set/p a=请输入(48位数字):

for /l %%i in (0,1,48) do (
	set/a "1!a:~%%i,1!1+1!a:~%%i,1!" 2>NUL || (
		echo;输入错误！请重新输入！
		goto :INPUT
	)
)

set/a "1/(1!a:~47,1!1-11)" 2>NUL || (
	echo;输入错误！请重新输入！
	goto :INPUT
)

set/a "1/(1!a:~48,1!1-11)" 2>NUL && (
	echo;输入错误！请重新输入！
	goto :INPUT
)

set/p=输入成功
复制代码

@echo off&setlocal enabledelayedexpansion
:a
set /p a=
for /f "delims=0123456789" %%a in ("%a%") do if not "%%a"=="" echo 不是纯数字&goto a
for /l %%a in (1,1,49) do if "!a:~%%a,1!"=="" set b=%%a&goto b
:b
echo %b%
if not "%b%"=="48" echo 不是48位
goto a
复制代码