[文本处理] 批处理如何按指定格式输出多个txt文本的文件名和指定行？

@echo off
echo ---------------------------------
echo output row 3 to a new txt.
echo ---------------------------------
:: Step1, Catch all txt file and save to namelist.txt
if exist namelist.txt del namelist.txt
if exist namelist.lst del namelist.lst
for %%i in (*.txt) do echo %%i>>namelist.lst
cd.>namelist.txt
for /f "tokens=1,2  delims=." %%J in (namelist.lst) do echo %%J >>namelist.txt
del namelist.lst

:: Step2, output row 3 to a new txt.
cd.>aa.txt
setlocal enabledelayedexpansion
for /f %%C in (namelist.txt) do (
        set n=0
        for /f "delims=" %%b in (%%C.txt) do (
            set /a n=n+1 
            if "!n!"=="3" echo %%C	%%b>>aa.txt
)
)

del namelist.txt
pause
复制代码

@echo off
(for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    set /p =%%~ni,<nul
    findstr "keyword=" "%%i"
))>aa.csv
复制代码

@echo off
(for %%a in (*.txt) do (
    call :getline "%%a"
))>"结果.csv"
pause&exit
:getline
for /f "skip=2 delims=" %%b in ('type "%~1"') do echo;%~n1,%%b&goto :eof
复制代码

@echo off
echo ---------------------------------
echo output row 3 to a new txt.
echo --------------------------------

:: Step2, output row 3 to a new txt.
::cd.>aa.txt
setlocal enabledelayedexpansion
for /f %%C in ('dir /b /a-d *.txt') do (
        set n=0
        for /f "delims=" %%b in (%%C) do (
            set /a n=n+1 
            if "!n!"=="3" echo %%C	%%b>>aa.txt
)
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
(for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    set n=0
    for /f "delims=" %%j in ('type "%%i"') do (
        set /a n+=1 
        if "!n!"=="3" (
            echo %%~ni,%%j
        )
    )
))>aa.csv
复制代码