[文件操作] [已解决]如何将html每一行做成单个的批处理？

@echo off
setlocal enableDelayedExpansion

set "AcrobatPath=D:\program files\pdf\Acrobat 11.0\Acrobat\Acrobat.exe"

for %%h in (*.htm) do (

    for /f "delims=" %%a in ('findstr /i /c:"<li><a href=" "%%h"') do (
        set "line=%%a"
        set "title=!line:~30,-9!"
        set "title=!title:*>=!"

        REM 去除文件名非法字符 / \ : ? " < > |
        for %%a in (/ \ : ^< ^> ^|) do (
            set "title=!title:%%a=_!"
        )
        (set title=!title:^"=_!)
        (set title=!title:?=_!)

        for /f tokens^=2-4^ delims^=#^". %%a in ("%%a") do (
            >!title!--%%a.bat (
                echo;start "" "%AcrobatPath%" /A "%%c" "F:\禅\%%a.pdf"
            )
        )
    )

)
pause
复制代码

@echo off
mshta http://bathome.net/s/hta/ type('0106.xml')^
    .match(/^<PATH^>[^^^>]+^<\/PATH^>^|^<PAGE^>[^^^>]+^<\/PAGE^>^|^<NAME^>[^^^>]+^<\/NAME^>/g)^
        .EACH(function(a){return a.replace(/^<[^^^>]+^>/g,'')})^
            .join('\r\n')>"结果.txt"
pause
复制代码

@echo off
mshta http://bathome.net/s/hta/ type('0106.xml')^
    ".match(/<PATH>[^>]+<\/PATH>|<PAGE>[^>]+<\/PAGE>|<NAME>[^>]+<\/NAME>/g)"^
        ".EACH(function(a){return a.replace(/<[^>]+>/g,'')})"^
            ".join('\r\n')" >"结果.txt"
pause
复制代码

["测\t试"]   相当于 [测	试]
[\"测\t试\"] 相当于 ["测	试"]
[""测\t试""] 相当于 ["测\t试"]
复制代码

@echo off
setlocal enableDelayedExpansion
set "AcrobatPath=D:\program files\pdf\Acrobat 11.0\Acrobat\Acrobat.exe"

for /f tokens^=2-3*delims^=^"# %%a in ('findstr /i /c:"<li><a href=" *.htm') do (
        set "title=%%c"
        set "title=!title:~1,-9!"
        set "title=!title:"=_!"
        set "title=!title:?=_!"
        for %%a in ( / \ : ^< ^> ^| ) do (
            set "title=!title:%%a=_!"
        )
        echo;start "" "%AcrobatPath%" /A "%%b" "%~dp0%%a">"!title!--%%~na.bat"
)
pause
复制代码