set wql=where "drive='%Desktop:~0,2%' and path='%MyPath:\=\\%' and extension!='LNK'"
复制代码

@echo off
set "s=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
for /f "tokens=2*" %%i in ('reg query "%s%" /v Desktop') do (
    set "Desktop=%%j"
)

set "MyPath=%Desktop:~2%\"
set wql=where "drive='%Desktop:~0,2%' and path='%MyPath:\=\\%' and extension!='LNK'"
(for /f "tokens=1*" %%i in ('wmic datafile %wql% get creationdate^,name^|find "\"') do (
    set "D=%%i"
    setlocal enabledelayedexpansion
    for %%k in ("%Desktop%\归档\!D:~0,8!") do (
        endlocal
        for /f "delims=" %%j in ("%%j") do (
            if /i not "%%~fj" == "%~f0" (
                md "%%~k\"
                move "%%~fj" "%%~k\"
            )
        )
    )
)) 2>nul
复制代码

@echo off
set "s=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
for /f "tokens=2*" %%i in ('reg query "%s%" /v Desktop') do (
    set "Desktop=%%j"
)
for /f %%i in ('wmic os get LocalDateTime^|findstr /b [0-9]') do (
    set "Today=%%i"
)

set "Today=%Today:~0,8%"
md "%Desktop%\归档\%Today%\" 2>nul

set "MyPath=%Desktop:~2%\"
set wql=where "drive='%Desktop:~0,2%' and path='%MyPath:\=\\%' and extension!='LNK'"
for /f "tokens=1*" %%i in ('wmic datafile %wql% get creationdate^,name^|findstr /b %Today%')do (
    for /f "delims=" %%j in ("%%j") do (
        if /i not "%%~fj" == "%~f0" move "%%~fj" "%Desktop%\归档\%Today%\"
    )
)
pause
复制代码