[其他] 【已解决】批处理怎样批量提取图片名及其尺寸？

@echo off
(for /r %%i in (*.jpg) do (
    echo "%%i"
    nconvert.exe -info "%%i" | findstr /c:"Width" /c:"Height"
))>l.txt
复制代码

@echo off

rem 获取图片尺寸示例
call  :getPicSize  "C:\Windows\Web\Wallpaper\Windows\img0.jpg"
if defined PicSize echo 图片尺寸: %PicSize%
pause

goto :eof
:getPicSize
  if not exist "%tmp%\getPicSize.vbs" (
    echo On Error Resume Next
    echo Set oImg=CreateObject^("WIA.ImageFile"^)
    echo If Not Err.Number=0 Then Msgbox "错误，系统缺失 WIA.ImageFile 组件！"
    echo oImg.LoadFile WScript.Arguments^(0^)
    echo If Not Err.Number=0 Then WScript.Quit^(1^)
    echo WScript.Echo oImg.Width ^& "x" ^& oImg.Height
    echo WScript.Quit^(0^)
  )>"%tmp%\getPicSize.vbs"
  set PicSize=
  for /f %%a in ('cscript.exe //nologo "%tmp%\getPicSize.vbs" "%~1"') do (set "PicSize=%%a")
  goto :eof
复制代码

/*&cls
@echo off
for /f "tokens=1* delims=|" %%a in ('dir /a-d /b /s *.jpg *.jpeg *.png^|cscript -nologo -e:jscript "%~f0"') do echo;%%~na_%%b%%~xa
pause&exit
*/

var objShell = new ActiveXObject('Shell.Application');
var fso = new ActiveXObject('Scripting.FileSystemObject');
var objFolder = objShell.NameSpace(0);
var i = 0;
while(true){if(objFolder.GetDetailsOf(null, i) == '尺寸'){break}else i++;}

while(!WSH.StdIn.AtEndOfStream){
        var f = fso.GetFile(WSH.StdIn.ReadLine());
        var objFolder = objShell.NameSpace(f.ParentFolder.Path);
        var objItem = objFolder.ParseName(f.Name);
        var size = objFolder.GetDetailsOf(objItem, i).match(/\d+/g).join('x');
        WSH.Echo(f.Path+ '|' +size);
}
复制代码

@echo off
powershell ^
    $wi=New-Object -com 'WIA.ImageFile';^
    dir . -inc *.jpg,*.jpeg,*.png -r^|%%{^
        $wi.LoadFile($_);^
        $_.Name+' '+$wi.Width+'x'+$wi.Height;^
    }
pause
复制代码

@if(0)==(0) echo off & dir /b /a-d /s *.jpg *.jpeg *.png 2>nul|cscript -NoLogo -E:JScript %0 >图片尺寸.txt & pause  & exit @end
var fso, Img;  
fso = new ActiveXObject("Scripting.FileSystemObject"); 
Img = new ActiveXObject("WIA.ImageFile");
while(!WScript.StdIn.AtEndOfStream){
    var f = fso.GetFile(WScript.StdIn.ReadLine());
    Img.LoadFile(f);
    WSH.Echo(fso.GetBaseName(f) + '_' + Img.Width + 'x' + Img.Height + '.' + fso.GetExtensionName(f));
}
复制代码