[文件管理] QQ聊天记录整理工具.bat

 
@echo off&setlocal enabledelayedexpansion&title QQ聊天记录整理工具 by cajibing
if "%~1" neq "" set "input=%1"&goto work
:start
cls&echo 导出QQ聊天记录的方法：一是使用手机QQ的导出功能，二是使用QQ本身的消息管理器：
echo     消息管理器——工具——导出全部消息记录——保存为文本文件txt。
echo 注意导出为文本文件TXT格式，编码转换为ANSI。如果文件名含有特殊符号可能导致失败！
echo;
set input=
set /p "input=    清理空记录【Y】请输入文本："&echo;
if /i "%input%"=="y" (
    for /f "tokens=*" %%a in ('dir /s /b *.txt') do (
        if "%%~za" neq "" if %%~za lss 300 findstr /sn .* "%%~a"|findstr ":6:"||echo;%%a&del /q "%%~a"
    )
    pause&goto start
)
:work
set num1=0
set num2=0
cd /d "%~dp0"
md 聊天记录
for /f "usebackq tokens=1* delims=:" %%a in ("%input%") do (
    if "%%a"=="消息分组"  (
        echo;消息分组:%%b
        set "pn=聊天记录\%%~b"
        set "pn=!pn:/=!"
        set "pn=!pn:^*=!"
        set "pn=!pn:?=!"
        set "pn=!pn:^:=!"
        set "pn=!pn:>=!"
        set "pn=!pn:<=!"
        set "pn=!pn:|=!"
        set "pn=!pn:"=!"
        if not exist "!pn!" md  "!pn!"&set /a num1+=1
        if not exist "!pn!" echo;——创建记录 "!pn!" 失败！
    )
    if "%%a"=="消息对象" (
        echo;消息对象:%%b
        set "fn=!pn!\%%~b.txt"
        set "fn=!fn:/=!"
        set "fn=!fn:^*=!"
        set "fn=!fn:?=!"
        set "fn=!fn:^:=!"
        set "fn=!fn:>=!"
        set "fn=!fn:<=!"
        set "fn=!fn:|=!"
        set "fn=!fn:"=!"
        cd.>"!fn!"
        if not exist "!fn!" (echo;——创建记录 "!fn!" 失败！) else set /a num2+=1
    )
    if exist "!fn!" echo;%%a:%%b>>"!fn!"
)
echo;
echo ——共 !num1! 个消息分组，!num2! 个消息对象。
echo;
pause&goto start
 
 
复制代码