【练习-029】批处理利用choice进行程序倒计时启动

@choice/c abcdefghijklmnopqrstuvwxyz1 /t 10 /d 1 >nul||if errorlevel 27 cmd
复制代码

@echo off
set "n=10"
:begin
cls&echo 请输入任意字母退出,否则10秒后程序将启动，计时：%n%秒
choice /c 1abcdefghijklmnopqrstuvwxyz /d 1 /t 1 /n
if %errorlevel% neq 1 goto :eof
set /a n-=1
if %n% neq 0 (goto begin) else (goto next)
:next
cls&echo 程序已启动&pause>nul
复制代码

@echo off
set "times=10"
echo 按任意键退出运行程序,默认 10 秒启动程序
:bgn
set/p=还剩下 %times% 秒...<nul
if "%times%"=="0" goto :run
set /a "times-=1"
choice /T 1 /C abcdefghijklmnopqrstuvwxyz /d a >nul
if "%errorlevel%"=="1" (goto :bgn) else (goto :end)
:run
echo.&echo 程序已经启动...
pause>nul&goto :eof
:end
echo.&echo 已经退出程序...
pause>nul
复制代码

@echo off
set "times=10"
echo 按任意字母键退出运行程序,默认 10 秒启动程序
:bgn
set/p=还剩下 %times% 秒...<nul
if "%times%"=="0" goto :run
set /a "times-=1"
choice /T 1 /C 0abcdefghijklmnopqrstuvwxyz /d 0 >nul
if "%errorlevel%"=="1" (goto :bgn) else (goto :end)
:run
echo.&echo 程序已经启动...
pause>nul&goto :eof
:end
echo.&echo 已经退出程序...
pause>nul
复制代码

@for /l %%a in (10,-1,0)do @cls&echo %%a&choice/c abcdefghijklmnopqrstuvwxyz1 /t 1 /d 1 >nul||if errorlevel 27 (if %%a==0 calc)else exit/b
复制代码

@echo off&setlocal enabledelayedexpansion
for /l %%i in (10,-1,0) do (
    cls&echo 请输入任意字母退出,否则10秒后程序将启动，计时：%%i秒
  choice /c 1abcdefghijklmnopqrstuvwxyz /d 1 /t 1 /n
    if !errorlevel! neq 1 goto :eof
)
cls&echo 程序已启动&pause>nul
复制代码

@echo off
set n=4
:LOOP
set /p =%n%<nul & set /a n-=1
Choice /c abcdefghijklmnopqrstuvwxyz1 /d 1 /t 1 /n>nul
if not errorlevel 27 exit /b
if %n% neq 0 goto :LOOP
echo. &echo 程序已经启动
pause
复制代码