【练习-067】批处理2012的基础练习

@echo off
for %%i in (2 0 1 2) do echo %%i
for /f "delims= tokens=1-4" %%i in ("2 0 1 2") do echo %%i %%j %%k %%l
pauseCOPY

for %%i in (xls word txt pdf gpg) do echo "2012 0">2012.%%iCOPY

@echo off&setlocal enabledelayedexpansion
set /p var=请输入四个字符（如2012）：
set v5=%var:~4,1%
echo.
if defined v5 echo 警告：输入超出4个字符，只显示前4个字符；&echo.
:4Rows
echo 分行输出（%var:~,4%）：
for %%i in (0 1 2 3) do echo !var:~%%i,1!
echo.
 
:1Row
echo 单行输出（%var:~,4%）:
echo %var:~,4%
echo.
 
:Reverse
echo 反序输出（%var:~,4%）:
echo %var:~3,1%%var:~2,1%%var:~1,1%%var:~,1%
 
pauseCOPY

@echo off
setlocal enabledelayedexpansion
 
set /p var=请输入计算各位数之和的四位数字（如2012）：
set v5=%var:~4,1%
echo.
if defined v5 echo 警告：输入超出4个字符，只操作前4个字符；&echo.
 
set var4=%var:~,4%
set /a sum=%var4%/1000+((%var4%%%1000)/100)+((%var4%%%100)/10)+((%var4%%%10)/1)
 
echo 四位数 %var4% 之和为 ：%sum%COPY

@echo off
set count=1
set target=2012
set /a mo=%target%+1
 
:loop
set /a var=%random%%%%mo%
if not %var% == %target% (
	set /a count=%count%+1
	goto :loop
	)
echo var = %var% 随机次数为：%count%COPY

@echo off
set count=1
set target=2012
set target2=0
set /a mo=%target%+1
 
:loop
set /a var=%random%%%%mo%
set /a target2=%target2%+%var%
echo 当前值：%target2%
if not %target2% == %target% (
	set /a count=%count%+1
	set /a mo=%mo%-%var%
	goto :loop
	)
echo 最后一次随机值 = %var% 随机次数为：%count%COPY

@echo off
set t=%time%
set target=2012
set /a n400=%target%%%400
set /a n4=%target%%%4
set /a n100=%target%%%100
if %n400% == 0 (echo %target% 是闰年&goto :eof)
if %n4% == 0 if not %n100% == 0 ( echo %target% 是闰年&goto :eof ) 
echo %target% 不是闰年COPY

@echo off & setlocal enabledelayedexpansion
for /l %%a in (1,1,10000000) do (
	if !random! EQU 2012 echo 运行了%%a次 && pause
	
)COPY

@echo off
set /p year=输入一个年份:
set /a run1=%year% %% 3200
set /a run2=%year% %% 172800
set /a run3=%year% %% 100
set /a run4=%year% %% 400
set /a run5=%year% %% 4
if %run1% equ 0 if %run2% equ 0 echo 闰年 & pause & exit
if %run3% equ 0 if %run4% equ 0 echo 闰年 & pause & exit
if %run5% equ 0 echo 闰年 & pause & exit
echo 平年
pauseCOPY

for %%i in (xls word txt pdf gpg) do (echo 2012 0)>2012.%%iCOPY

@echo off
 
call :Conver 2213
call :Conver 2012
 
:Conver
setlocal enabledelayedexpansion
set count=0
set tem=%1
set num=零 一 二 三 四 五 六 七 八 九
for %%a in (%num%) do (
	set !count!=%%a
	set /a count+=1
)
echo !%tem:~,1%!!%tem:~1,1%!!%tem:~2,1%!!%tem:~3,1%!
pauseCOPY

@echo off & setlocal enabledelayedexpansion
set a=零,一千,二千,三千,四千,五千,六千,七千,八千,九千
set b=零,一百,二百,三百,四百,五百,六百,七百,八百,九百
set c=零,一十,二十,三十,四十,五十,六十,七十,八十,九十
set d=零,一,二,三,四,五,六,七,八,九
for %%a in (%q%) do (
	for %%b in (%b%) do (
		for %%c in (%s%) do (
			for %%d in (%g%) do (
			if %%a EQU 零 if %%b EQU 零 if %%c EQU 零 echo %%d
			if %%a EQU 零 if %%b EQU 零 if %%c NEQ 零 echo %%c%%d
			if %%a EQU 零 if %%b NEQ 零 echo %%b%%c%%d
			if %%a NEQ 零 echo %%a%%b%%c%%d
			set /a count+=1
			if !count! EQU 2012 pause
)
)
)
)
pauseCOPY

@echo off
:start
cls&set/p str=请输入一个4位数：
if "%str:~,-3%"=="" goto start
if not "%str:~4%"=="" goto start
echo 分行输出:&(for /l %%a in (0 1 3) do call echo %%str:~%%a,1%%)
echo 同行输出:&(for /l %%a in (0 1 3) do call set/p=%%str:~%%a,1%% <nul)
echo.&echo 反序输出:&(for /l %%a in (3 -1 0) do call set/p=%%str:~%%a,1%%<nul)
echo.&pauseCOPY

@echo off
:start
cls&set/p str=请输入一个4位数：
if "%str:~,-3%"=="" goto start
if not "%str:~4%"=="" goto start
for /l %%a in (0 1 3) do call set/a sum+=%%str:~%%a,1%%
echo 4个数值的和: %sum%&pauseCOPY

@echo off
set n=0&set str=
call :loop 2 0 1 2
echo %str%运行了%n%次&pause&exit
 
:loop
if "%1"=="" goto :eof
set/a n+=1&set aa=%random:~-1%
if "%aa%"=="%1" (set str=%str%%aa%&shift&goto loop) else goto loopCOPY

@echo off
set n=0
set min=0&set max=2012
:loop
set/a n+=1
set/a mod=%max%-%min%+1
set /a str=%random%%%%mod%+%min%
echo 第%n%次	%str%
if not "%str%"=="%max%" set min=%str%&goto loop
pauseCOPY

@echo off
set/p input=请输入年份(如2012):
set/a "year=!(%input%%%4)&!(!(%input%%%100))|!(%input%%%400)"
if "%year%"=="1" (echo 闰年) else echo 平年
pauseCOPY

@echo off&setlocal enabledelayedexpansion
for /l %%a in (1 1 12) do (
   set month=%%a&set day=31
   set/a m=!month!%%2
   if !month! geq 8 (if !m! equ 1 set/a day-=1) else if !m! equ 0 set/a day-=1
   if !month! equ 2 set/a day-=1
   for /l %%b in (1 1 !day!) do set/p=2012/!month!/%%b <nul
   echo.
)
pauseCOPY

@echo off
set "str=2012　0" 
for %%a in (xls doc txt pdf jpg) do call echo %%str%%>2012.%%aCOPY

@echo off&setlocal enabledelayedexpansion
:start
cls&set/p input=请输入一个4位数：
if "!input:~,-3!"=="" goto start
if not "!input:~4!"=="" goto start
:loop
for %%i in (1一 2二 3三 4四 5五 6六 7七 8八 9九 0零) do (
        set "var=%%i"
        if "!input:~,1!"=="!var:~,1!" set str=!str!!var:~1,1!&goto shift
       )
 
:shift
set "input=!input:~1!"
if not "!input!"=="" goto loop
echo !str!
pauseCOPY

@echo off&setlocal enabledelayedexpansion
set str=&set output=
echo 正在生成result.txt文件, 请稍候...
(for /l %%a in (1 1 2012) do (
    set str=%%a
    for %%b in (1一 2二 3三 4四 5五 6六 7七 8八 9九 0零) do (
        set var=%%b&set m=!var:~,1!&set n=!var:~1,1!
        call set str=%%str:!m!=!n!%%
    )
    if "!str:~4!"=="" set output=!str:~,1!千!str:~1,1!百!str:~2,1!十!str:~3,1!
    if "!str:~3!"=="" set output=!str:~,1!百!str:~1,1!十!str:~2,1!
    if "!str:~2!"=="" set output=!str:~,1!十!str:~1,1!
    if "!str:~1!"=="" set output=!str:~,1!
    set output=!output:零百=零!&set output=!output:零十=零!
    set output=!output:零零零=零!&set output=!output:零零=零!
    if "!output:~-1!"=="零" set output=!output:~,-1!
    if "!output:~,1!"=="零" set output=!output:~1!
    if "!output:~,2!"=="一十" set output=!output:~1!
    set/p=!output! <nul
))>result.txtCOPY

@echo off&setlocal enabledelayedexpansion
set "str1=2012年，祝愿大家："
set "str2=天天好心情！"
set "str3=事事随心愿！"
for /l %%a in (1 1 3) do set n=0&set str=!str%%a!&call :loop
echo.&pause
 
:loop
if "!str:~%n%!"=="" echo.&goto :eof
set/p=!str:~%n%,1!<nul&set/a n+=1
for /l %%b in (1 1 500) do echo %%b>nul
goto loopCOPY

@echo off&set b=&set a=2012
:1
if "%a%"=="" goto 2
echo %a:~0,1%
set "b=%b%%a:~0,1% "&set "a=%a:~1%"
goto 1
:2
echo 结果是：%b%&pause>nulCOPY

@echo off&setlocal EnableDelayedExpansion
set a=2012
:1
If defined a (
  set "c=%c%%a:~-1%"
  set "a=%a:~,-1%"
  goto 1
)
echo %c%&pauseCOPY

@echo off&setlocal EnableDelayedExpansion&set b=&set a=2012&set c=0
:1
if "%a%"=="" goto 2
set "b=%b%%a:~0,1% "&set "a=%a:~1%"
goto 1
:2
for %%i in (%b%) do set /a c+=%%i
echo !c!&pauseCOPY

@echo off&set a=0
:1
if not "%random%"=="2012" (set /a a+=1&goto 1) else echo 运行了%a%次 random=2012&pauseCOPY

@echo off&setlocal enabledelayedexpansion&set /a c=1,zs=0,zd=32767
set "tab=        "
::请把以上的tab换成实际的制表符 为了显示好看点
:1
set /a a=%random%%%((zd+1)-zs)+zs
set "ml=echo !c!次%tab%%a%%tab%最多%zd%%tab%最少%zs%"
if %a% lss 2012 set /a zs=%a%+1&%ml%&set /a c+=1
if %a% gtr 2012 set /a zd=%a%-1&%ml%&set /a c+=1
if %a% equ 2012 (%ml%&pause>nul&exit)
goto 1COPY

@set /a "yp=!(2012%%4)&!(!(2012%%100))|!(2012%%400)"
@if "%yp%"=="1" (@echo 闰年) else (@echo 平年)
@pauseCOPY

@echo off&setlocal EnableDelayedExpansion&set n=0&set year=2012&set /a "yp=^!(year%%4)&^!(^!(year%%100))|^!(year%%400)+28"
for %%a in (31 !yp! 31 30 31 30 31 31 30 31 30 31) do (set /a n+=1&for /l %%i in (1,1,%%a) do echo %year%年!n!月%%i日)
pauseCOPY

@for %%i in (xls doc txt pdf gpg) do ((@echo 2012 0)>2012.%%i)COPY

@echo off&setlocal enabledelayedexpansion&set a=2012
for %%i in (零0 一1 二2 三3 四4 五5 六6 七7 八8 九9) do (set b=%%i&call:1 !b:~1! !b:~0,1!)
echo !a! &pause&exit
:1
set a=!a:%1=%2!COPY

@echo off&setlocal enabledelayedexpansion
echo 正在初始化中....
for /l %%a in (1,1,9) do (
  set n%%a00=%%a百
  set n%%a000=%%a千
  set n%%a=%%a
  if not "%%a"=="1" set i=%%a
  set n%%a0=!i!十
  for /l %%b in (1,1,9) do (
    set n%%a%%b0=%%a百%%b十
    set n%%a%%b00=%%a千%%b百
        set n%%a%%b=!i!十%%b
    for /l %%c in (1,1,9) do (
      set n%%a%%b%%c=%%a百%%b十%%c
      set n%%a0%%c=%%a百零%%c
      set n%%a%%b%%c0=%%a千%%b百%%c十
      set n%%a0%%c0=%%a千零%%c十
      for /l %%d in (1,1,9) do (
        set n%%a00%%d=%%a千零%%d
        set n%%a0%%c%%d=%%a千零%%c十%%d
        set n%%a%%b0%%d=%%a千%%b百零%%d
        set n%%a%%b%%c%%d=%%a千%%b百%%c十%%d
        if "%%a%%b%%c%%d"=="2012" call:end 
      )
    )
  )
)
:end
for /l %%a in (1,1,2012) do (
  set a=!n%%a!
  for %%i in (一1 二2 三3 四4 五5 六6 七7 八8 九9 零0) do (
    set b=%%i
    call:1 !b:~1! !b:~0,1!
  )
  echo !a!
)
pause>nul
:1
set a=!a:%1=%2!COPY

@echo off&setlocal enabledelayedexpansion
echo 正在初始化中....
for /l %%a in (1,1,9) do (
  set n%%a00=%%a百
  set n%%a000=%%a千
  set n%%a=%%a
  if not "%%a"=="1" set i=%%a
  set n%%a0=!i!十
  for /l %%b in (1,1,9) do (
    set n%%a%%b0=%%a百%%b十
    set n%%a%%b00=%%a千%%b百
        set n%%a%%b=!i!十%%b
    for /l %%c in (1,1,9) do (
      set n%%a%%b%%c=%%a百%%b十%%c
      set n%%a0%%c=%%a百零%%c
      set n%%a%%b%%c0=%%a千%%b百%%c十
      set n%%a0%%c0=%%a千零%%c十
      for /l %%d in (1,1,9) do (
        set n%%a00%%d=%%a千零%%d
        set n%%a0%%c%%d=%%a千零%%c十%%d
        set n%%a%%b0%%d=%%a千%%b百零%%d
        set n%%a%%b%%c%%d=%%a千%%b百%%c十%%d
        if "%%a%%b%%c%%d"=="2012" call:end 
      )
    )
  )
)
:end
set c=0
:2
set /a c+=1
set a=!n%c%!
set a=!a:1=一!
set a=!a:2=二!
set a=!a:3=三!
set a=!a:4=四!
set a=!a:5=五!
set a=!a:6=六!
set a=!a:7=七!
set a=!a:8=八!
set a=!a:9=九!
set a=!a:0=零!
echo !a!
if not "%c%"=="2012" goto 2
pause>nulCOPY

@echo off
call:2 "2012 年 祝 大 家 ："
call:2 "心 想 事 成"
call:2 "万 事 如 意"
call:2 "最 后 祝 大 家"
call:2 "在 2012 年 12 月 22 日 能 存 活 下 来 . . . . . ."
set x=0
set color=0123456789abcdef
:3
set /a x+=1
set /a ra=%random%%%16
cmd /v:on /c color !color:~%ra%,1!
if "%x%"=="70" exit
goto 3
:2
set "b=%~1"
for %%i in (%b%) do (
  set /p "a=%%i"<nul
  for /l %%x in (1,1,1000) do ver>nul
)
echo.COPY